mirror of
https://github.com/waku-org/nwaku.git
synced 2025-02-12 15:06:38 +00:00
385daf16be
* on_chain/group_manager: use .async: (raises:[Exception]). * bump nim-dnsdisc * update nim-chronos to the latest state * chat2.nim: catch any possible exception when stopping * chat2bridge.nim: make it to compile after vendor bump * ValidIpAddress (deprecated) -> IpAddress * vendor/nim-libp2p additional bump * libwaku: adapt to vendor bump * testlib/wakunode.nim: adapt to vendor bump (ValidIpAddress -> IpAddress) * waku_node: avoid throwing any exception from stop*(node: WakuNode) * test_confutils_envvar.nim: ValidIpAddress -> IpAddress * test_jsonrpc_store: capture exception * test_rln*: handling exceptions * adaptation to make test_rln_* to work properly * signature enhancement of group_manager methods
68 lines
2.0 KiB
Nim
68 lines
2.0 KiB
Nim
|
|
when (NimMajor, NimMinor) < (1, 4):
|
|
{.push raises: [Defect].}
|
|
else:
|
|
{.push raises: [].}
|
|
|
|
import
|
|
std/[options, strutils]
|
|
import
|
|
chronicles,
|
|
eth/net/nat,
|
|
stew/results,
|
|
stew/shims/net,
|
|
nativesockets
|
|
|
|
logScope:
|
|
topics = "nat"
|
|
|
|
proc setupNat*(natConf, clientId: string,
|
|
tcpPort, udpPort: Port):
|
|
Result[tuple[ip: Option[IpAddress],
|
|
tcpPort: Option[Port],
|
|
udpPort: Option[Port]], string]
|
|
{.gcsafe.} =
|
|
|
|
let strategy = case natConf.toLowerAscii():
|
|
of "any": NatAny
|
|
of "none": NatNone
|
|
of "upnp": NatUpnp
|
|
of "pmp": NatPmp
|
|
else: NatNone
|
|
|
|
var endpoint: tuple[ip: Option[IpAddress], tcpPort: Option[Port], udpPort: Option[Port]]
|
|
|
|
if strategy != NatNone:
|
|
let extIp = getExternalIP(strategy)
|
|
if extIP.isSome():
|
|
endpoint.ip = some(extIp.get())
|
|
# RedirectPorts in considered a gcsafety violation
|
|
# because it obtains the address of a non-gcsafe proc?
|
|
var extPorts: Option[(Port, Port)]
|
|
try:
|
|
extPorts = ({.gcsafe.}: redirectPorts(tcpPort = tcpPort,
|
|
udpPort = udpPort,
|
|
description = clientId))
|
|
except CatchableError:
|
|
# TODO: nat.nim Error: can raise an unlisted exception: Exception. Isolate here for now.
|
|
error "unable to determine external ports"
|
|
extPorts = none((Port, Port))
|
|
|
|
if extPorts.isSome():
|
|
let (extTcpPort, extUdpPort) = extPorts.get()
|
|
endpoint.tcpPort = some(extTcpPort)
|
|
endpoint.udpPort = some(extUdpPort)
|
|
|
|
else: # NatNone
|
|
if not natConf.startsWith("extip:"):
|
|
return err("not a valid NAT mechanism: " & $natConf)
|
|
|
|
try:
|
|
# any required port redirection is assumed to be done by hand
|
|
endpoint.ip = some(parseIpAddress(natConf[6..^1]))
|
|
except ValueError:
|
|
return err("not a valid IP address: " & $natConf[6..^1])
|
|
|
|
return ok(endpoint)
|
|
|