mirror of https://github.com/vacp2p/research.git
33 lines
1.7 KiB
Plaintext
33 lines
1.7 KiB
Plaintext
telephone-uri = "tel:" telephone-subscriber
|
|
telephone-subscriber = global-number / local-number
|
|
global-number = global-number-digits *par
|
|
local-number = local-number-digits *par context *par
|
|
par = parameter / extension / isdn-subaddress
|
|
isdn-subaddress = ";isub=" 1*uric
|
|
extension = ";ext=" 1*phonedigit
|
|
context = ";phone-context=" descriptor
|
|
descriptor = domainname / global-number-digits
|
|
global-number-digits = "+" *phonedigit DIGIT *phonedigit
|
|
local-number-digits =
|
|
*phonedigit-hex (HEXDIG / "*" / "#") *phonedigit-hex
|
|
domainname = *( domainlabel "." ) toplabel [ "." ]
|
|
domainlabel = alphanum
|
|
/ alphanum *( alphanum / "-" ) alphanum
|
|
toplabel = ALPHA / ALPHA *( alphanum / "-" ) alphanum
|
|
parameter = ";" pname ["=" pvalue ]
|
|
pname = 1*( alphanum / "-" )
|
|
pvalue = 1*paramchar
|
|
paramchar = param-unreserved / unreserved / pct-encoded
|
|
unreserved = alphanum / mark
|
|
mark = "-" / "_" / "." / "!" / "~" / "*" /
|
|
"'" / "(" / ")"
|
|
pct-encoded = "%" HEXDIG HEXDIG
|
|
param-unreserved = "[" / "]" / "/" / ":" / "&" / "+" / "$"
|
|
phonedigit = DIGIT / [ visual-separator ]
|
|
phonedigit-hex = HEXDIG / "*" / "#" / [ visual-separator ]
|
|
visual-separator = "-" / "." / "(" / ")"
|
|
alphanum = ALPHA / DIGIT
|
|
reserved = ";" / "/" / "?" / ":" / "@" / "&" /
|
|
"=" / "+" / "$" / ","
|
|
uric = reserved / unreserved / pct-encoded
|