mirror of
https://github.com/vacp2p/nim-libp2p-experimental.git
synced 2025-01-25 01:29:24 +00:00
7900fd9f61
* call write until all is written out * add comments to lpchannel fields * add an eof flag to signal which end closed * wip: rework with proper half-closed * add eof and closed handling * propagate closes to piped * call parent close * moving bufferstream trackers out * move writeLock to bufferstream * move writeLock out * remove unused call * wip * rebasing master * fix mplex tests * wip * fix bufferstream after backport * wip * rename to differentiate from chronos tracker * close connection on chronos close * make reset request asyncCheck * fix channel cleanup * misc * don't use read * fix backports * make noise work again * proper exception handling * don't reraise just yet * add convenience templates * dont double wrap * use async pragma * fixes after backporting * muxer owns connection * remove on transport close cleanup * revert back allread * adding some todos * read from stream * inc count before closing * rebasing master * rebase master * use correct exception type * use try/finally insted of defer * fix compile in trace mode * reset channels on mplex close
93 lines
2.9 KiB
Nim
93 lines
2.9 KiB
Nim
## Nim-LibP2P
|
|
## Copyright (c) 2019 Status Research & Development GmbH
|
|
## Licensed under either of
|
|
## * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE))
|
|
## * MIT license ([LICENSE-MIT](LICENSE-MIT))
|
|
## at your option.
|
|
## This file may not be copied, modified, or distributed except according to
|
|
## those terms.
|
|
|
|
import options
|
|
import chronos, chronicles
|
|
import ../protocol,
|
|
../../stream/streamseq,
|
|
../../connection,
|
|
../../peerinfo
|
|
|
|
type
|
|
Secure* = ref object of LPProtocol # base type for secure managers
|
|
|
|
SecureConn* = ref object of Connection
|
|
buf: StreamSeq
|
|
|
|
method readMessage*(c: SecureConn): Future[seq[byte]] {.async, base.} =
|
|
doAssert(false, "Not implemented!")
|
|
|
|
method handshake(s: Secure,
|
|
conn: Connection,
|
|
initiator: bool): Future[SecureConn] {.async, base.} =
|
|
doAssert(false, "Not implemented!")
|
|
|
|
proc handleConn*(s: Secure, conn: Connection, initiator: bool): Future[Connection] {.async, gcsafe.} =
|
|
var sconn = await s.handshake(conn, initiator)
|
|
|
|
result = sconn
|
|
|
|
if not isNil(sconn.peerInfo) and sconn.peerInfo.publicKey.isSome:
|
|
result.peerInfo = PeerInfo.init(sconn.peerInfo.publicKey.get())
|
|
|
|
method init*(s: Secure) {.gcsafe.} =
|
|
proc handle(conn: Connection, proto: string) {.async, gcsafe.} =
|
|
trace "handling connection upgrade", proto
|
|
try:
|
|
# We don't need the result but we definitely need to await the handshake
|
|
discard await s.handleConn(conn, false)
|
|
trace "connection secured"
|
|
except CatchableError as exc:
|
|
if not conn.closed():
|
|
warn "securing connection failed", msg = exc.msg
|
|
await conn.close()
|
|
|
|
s.handler = handle
|
|
|
|
method secure*(s: Secure, conn: Connection, initiator: bool): Future[Connection] {.async, base, gcsafe.} =
|
|
try:
|
|
result = await s.handleConn(conn, initiator)
|
|
except CatchableError as exc:
|
|
warn "securing connection failed", msg = exc.msg
|
|
await conn.close()
|
|
|
|
method readExactly*(s: SecureConn,
|
|
pbytes: pointer,
|
|
nbytes: int):
|
|
Future[void] {.async, gcsafe.} =
|
|
if nbytes == 0:
|
|
return
|
|
|
|
while s.buf.data().len < nbytes:
|
|
# TODO write decrypted content straight into buf using `prepare`
|
|
let buf = await s.readMessage()
|
|
if buf.len == 0:
|
|
raise newLPStreamIncompleteError()
|
|
s.buf.add(buf)
|
|
|
|
var p = cast[ptr UncheckedArray[byte]](pbytes)
|
|
let consumed = s.buf.consumeTo(toOpenArray(p, 0, nbytes - 1))
|
|
doAssert consumed == nbytes, "checked above"
|
|
|
|
method readOnce*(s: SecureConn,
|
|
pbytes: pointer,
|
|
nbytes: int):
|
|
Future[int] {.async, gcsafe.} =
|
|
if nbytes == 0:
|
|
return 0
|
|
|
|
if s.buf.data().len() == 0:
|
|
let buf = await s.readMessage()
|
|
if buf.len == 0:
|
|
raise newLPStreamIncompleteError()
|
|
s.buf.add(buf)
|
|
|
|
var p = cast[ptr UncheckedArray[byte]](pbytes)
|
|
return s.buf.consumeTo(toOpenArray(p, 0, nbytes - 1))
|