mirror of
https://github.com/status-im/status-react.git
synced 2025-01-10 19:16:59 +00:00
1ee16da0c7
nix: use nixpkgs unstable for gradle 8.8 nix: ldflags are expected to be a list chore: fix deprecated vendorSha256 nix: bump jdk to 17 & pass java version to gradle make: set universalApk false in run-android target nix: fix --replace deprecation warning - https://github.com/NixOS/nixpkgs/pull/260776 ios: update pod and gem lockfiles nix: bump nodejs to 20.12.2 nix: add Xcode 16.0 to allowed versions chore: upgrade rn-image-crop-picker lib nix: full path for missing dep in node_modules sh e2e: removed redundant element --------- Co-authored-by: Yevheniia Berdnyk <ie.berdnyk@gmail.com>
86 lines
2.8 KiB
Nix
86 lines
2.8 KiB
Nix
#
|
|
# This Nix expression builds the js files for the current repository given a node modules Nix expression
|
|
#
|
|
|
|
{ stdenv, lib, deps, pkgs }:
|
|
|
|
# Path to the file containing secret environment variables
|
|
{ secretsFile ? "" }:
|
|
|
|
stdenv.mkDerivation {
|
|
name = "status-mobile-jsbundle";
|
|
src =
|
|
let path = ./../../..;
|
|
# We use builtins.path so that we can name the resulting derivation,
|
|
# otherwise the name would be taken from the checkout directory,
|
|
# which is outside of our control inherit path;
|
|
in builtins.path {
|
|
inherit path;
|
|
name = "status-mobile-source-jsbundle";
|
|
filter =
|
|
# Keep this filter as restrictive as possible in order to avoid
|
|
# unnecessary rebuilds and limit closure size
|
|
lib.mkFilter {
|
|
root = path;
|
|
ignoreVCS = false;
|
|
include = [
|
|
"VERSION" "BUILD_NUMBER" "scripts/version/.*"
|
|
"src/.*" "shadow-cljs.edn"
|
|
# I want to avoid including the whole .git directory
|
|
".git/HEAD" ".git/objects" ".git/refs/heads/.*"
|
|
# shadow-cljs expects these for deps resolution
|
|
"package.json" "yarn.lock"
|
|
# build stat's images to check if they exist
|
|
"resources/.*" "translations/.*"
|
|
];
|
|
exclude = [
|
|
"resources/fonts/.*"
|
|
];
|
|
};
|
|
};
|
|
buildInputs = with pkgs; [ clojure nodejs bash git openjdk];
|
|
phases = [
|
|
"unpackPhase" "secretsPhase" "patchPhase"
|
|
"configurePhase" "buildPhase" "installPhase"
|
|
];
|
|
|
|
# For optional POKT_TOKEN variable
|
|
secretsPhase = if (secretsFile != "") then ''
|
|
source "${secretsFile}"
|
|
${lib.checkEnvVarSet "POKT_TOKEN"}
|
|
'' else ''
|
|
echo "No secrets provided!"
|
|
'';
|
|
|
|
# Patching shadow-cljs.edn so it uses the local maven repo of dependencies provided by Nix
|
|
patchPhase =
|
|
let anchor = ''{:source-paths ["src" "test/cljs"]'';
|
|
in ''
|
|
substituteInPlace shadow-cljs.edn \
|
|
--replace-quiet '${anchor}' \
|
|
'${anchor}
|
|
:maven {:local-repo "${deps.clojure}"}'
|
|
'';
|
|
configurePhase = ''
|
|
# Symlink Node.js modules to build directory
|
|
ln -s ${deps.nodejs}/node_modules
|
|
'';
|
|
buildPhase = ''
|
|
# Assemble CLASSPATH from available clojure dependencies.
|
|
# We prepend 'src' so it can find the local sources and prioritize
|
|
# our own namespaces over dependencies, given that indirect dependencies
|
|
# can also cause naming conflicts (e.g. prismatic/schema already uses
|
|
# namespace schema.core).
|
|
export CLASS_PATH="src:$(find ${deps.clojure} \
|
|
-iname '*.jar' | tr '\n' ':')"
|
|
|
|
# target must be one of the builds defined in shadow-cljs.edn
|
|
java -cp "$CLASS_PATH" clojure.main \
|
|
-m shadow.cljs.devtools.cli release mobile
|
|
'';
|
|
installPhase = ''
|
|
mkdir -p $out
|
|
cp -r result/* $out/
|
|
'';
|
|
}
|