mirror of
https://github.com/status-im/status-react.git
synced 2025-01-10 11:06:25 +00:00
Jakub Sokołowski
939ce8bef5
This makes use of the refactoring of Android SDK done in: https://github.com/NixOS/nixpkgs/pull/89775 Which allows us to drop the use of our own fork of `nixpkgs`. Android Upgrades: * Build Tools - `29.0.2` to `30.0.3` * Platform Tools - `29.0.6` to `30.0.5` * NDK Bundle - `21.0.6113669` to `21.3.6528147` Other Upgrades: * Git - `2.28.0` to `2.29.2` * Go - `1.14.7` to `1.14.13` * Clojure - `1.10.1.645` to `1.10.1.763` * NodeJS - `12.18.3` to `12.20.1` * Yarn - `1.22.4` to `1.22.10` * OpenJDK - `8u265-ga` to `8u272-b10` * PatchElf - `0.11` to `0.12` * CoreUtils - `8.31` to `8.32` Signed-off-by: Jakub Sokołowski <jakub@status.im>
55 lines
1.6 KiB
Nix
55 lines
1.6 KiB
Nix
# Override some packages and utilities in 'pkgs'
|
|
# and make them available globally via callPackage.
|
|
#
|
|
# For more details see:
|
|
# - https://nixos.wiki/wiki/Overlays
|
|
# - https://nixos.org/nixos/nix-pills/callpackage-design-pattern.html
|
|
|
|
self: super:
|
|
|
|
let inherit (super) stdenv stdenvNoCC callPackage;
|
|
in {
|
|
# Fix for MacOS
|
|
mkShell = super.mkShell.override { stdenv = stdenvNoCC; };
|
|
|
|
# Various utilities
|
|
utils = callPackage ./tools/utils.nix { };
|
|
lib = (super.lib or { }) // (import ./lib {
|
|
inherit (super) lib;
|
|
inherit (self) config;
|
|
});
|
|
|
|
# Project dependencies
|
|
deps = {
|
|
clojure = callPackage ./deps/clojure { };
|
|
gradle = callPackage ./deps/gradle { };
|
|
nodejs = callPackage ./deps/nodejs { };
|
|
nodejs-patched = callPackage ./deps/nodejs-patched { };
|
|
react-native = callPackage ./deps/react-native { };
|
|
};
|
|
|
|
# For parsing gradle.properties into an attrset
|
|
gradlePropParser = callPackage ./tools/gradlePropParser.nix { };
|
|
|
|
# Package version adjustments
|
|
go = super.pkgs.go_1_14;
|
|
gradle = super.pkgs.gradle_5;
|
|
nodejs = super.pkgs.nodejs-12_x;
|
|
openjdk = super.pkgs.openjdk8_headless;
|
|
xcodeWrapper = callPackage ./pkgs/xcodeenv/compose-xcodewrapper.nix { } {
|
|
version = "11.5";
|
|
allowHigher = true;
|
|
};
|
|
|
|
# Android environement
|
|
androidEnvCustom = callPackage ./pkgs/android-sdk { };
|
|
androidPkgs = self.androidEnvCustom.pkgs;
|
|
androidShell = self.androidEnvCustom.shell;
|
|
|
|
# Custom packages
|
|
aapt2 = callPackage ./pkgs/aapt2 { };
|
|
gomobile = callPackage ./pkgs/gomobile { };
|
|
patchMavenSources = callPackage ./pkgs/patch-maven-srcs { };
|
|
goMavenResolver = callPackage ./pkgs/go-maven-resolver { };
|
|
}
|