mirror of
https://github.com/status-im/status-mobile.git
synced 2025-01-10 08:45:58 +00:00
Jakub Sokołowski
c97559793c
Notable upgrades: * Bash `5.1` to `5.2` * Git `2.37.3` to `2.40.1` * Curl `7.85.0` to `8.0.1` * OpenSSL `3.0.5` to `3.0.8` * Go `1.18.6` to `1.18.9` * NodeJS `18.9.1` to `18.16.0` * Java `1.8.0_322` to `11.0.11` * Ruby `3.1.2` to `3.1.4` * Python `2.7.18` to `3.10.11` * Clojure `1.11.1.1165` to `1.11.1.1273` * Clj-kondo `v2022.10.05` to `v2023.04.14` * Zprint `1.2.5` to `1.2.6` * Bundler `2.3.22` to `2.4.13` * Gradle `6.9.2` to `6.9.4` * Android Platform Tools `33.0.2` to `33.0.3` * Android SDK Tools to Android SDK Command-Line Tools Removals: * Zprint since the version in `nixpkgs` was newer than in overlay. * Xcode wrapper definition was removed since my fixes were merged: - https://github.com/NixOS/nixpkgs/pull/204278 - https://github.com/NixOS/nixpkgs/pull/228696 Signed-off-by: Jakub Sokołowski <jakub@status.im>
80 lines
2.6 KiB
Nix
80 lines
2.6 KiB
Nix
# Override some packages and utilities in 'pkgs'
|
|
# and make them available globally via callPackage.
|
|
#
|
|
# For more details see:
|
|
# - https://nixos.wiki/wiki/Overlays
|
|
# - https://nixos.org/nixos/nix-pills/callpackage-design-pattern.html
|
|
|
|
self: super:
|
|
|
|
let
|
|
inherit (super) stdenv stdenvNoCC callPackage;
|
|
in {
|
|
# Fix for MacOS
|
|
mkShell = super.mkShell.override { stdenv = stdenvNoCC; };
|
|
|
|
# Various utilities
|
|
utils = callPackage ./tools/utils.nix { };
|
|
lib = (super.lib or { }) // (import ./lib {
|
|
inherit (super) lib;
|
|
inherit (self) config;
|
|
});
|
|
|
|
# Project dependencies
|
|
deps = {
|
|
clojure = callPackage ./deps/clojure { };
|
|
gradle = callPackage ./deps/gradle { };
|
|
nodejs = callPackage ./deps/nodejs { };
|
|
nodejs-patched = callPackage ./deps/nodejs-patched { };
|
|
react-native = callPackage ./deps/react-native { };
|
|
};
|
|
|
|
# For parsing gradle.properties into an attrset
|
|
gradlePropParser = callPackage ./tools/gradlePropParser.nix { };
|
|
|
|
# Fix for missing libarclite_macosx.a in Xcode 14.3.
|
|
# https://github.com/ios-control/ios-deploy/issues/580
|
|
ios-deploy = super.darwin.ios-deploy.overrideAttrs (old: rec {
|
|
version = "1.12.2";
|
|
src = super.fetchFromGitHub {
|
|
owner = "ios-control";
|
|
repo = "ios-deploy";
|
|
rev = version;
|
|
sha256 = "sha256-TVGC+f+1ow3b93CK3PhIL70le5SZxxb2ug5OkIg8XCA";
|
|
};
|
|
});
|
|
|
|
# Package version adjustments
|
|
gradle = super.gradle_7;
|
|
nodejs = super.nodejs-18_x;
|
|
yarn = super.yarn.override { nodejs = super.nodejs-18_x; };
|
|
openjdk = super.openjdk11_headless;
|
|
xcodeWrapper = super.xcodeenv.composeXcodeWrapper {
|
|
version = "14.0";
|
|
allowHigher = true;
|
|
};
|
|
go = super.go_1_19;
|
|
buildGoPackage = super.buildGo119Package;
|
|
buildGoModule = super.buildGo119Module;
|
|
gomobile = (super.gomobile.overrideAttrs (old: {
|
|
patches = self.fetchurl { # https://github.com/golang/mobile/pull/84
|
|
url = "https://github.com/golang/mobile/commit/f20e966e05b8f7e06bed500fa0da81cf6ebca307.patch";
|
|
sha256 = "sha256-TZ/Yhe8gMRQUZFAs9G5/cf2b9QGtTHRSObBFD5Pbh7Y=";
|
|
};
|
|
})).override {
|
|
# FIXME: No Android SDK packages for aarch64-darwin.
|
|
withAndroidPkgs = stdenv.system != "aarch64-darwin";
|
|
androidPkgs = self.androidEnvCustom.compose;
|
|
};
|
|
|
|
# Android environement
|
|
androidEnvCustom = callPackage ./pkgs/android-sdk { };
|
|
androidPkgs = self.androidEnvCustom.pkgs;
|
|
androidShell = self.androidEnvCustom.shell;
|
|
|
|
# Custom packages
|
|
aapt2 = callPackage ./pkgs/aapt2 { };
|
|
patchMavenSources = callPackage ./pkgs/patch-maven-srcs { };
|
|
goMavenResolver = callPackage ./pkgs/go-maven-resolver { };
|
|
}
|