mirror of
https://github.com/status-im/status-go.git
synced 2025-01-09 14:16:21 +00:00
6ee62061bc
- Added support for Windows and macOS in CI pipelines - Added missing dependencies for Windows and x86-64-darwin - Resolved macOS SDK version compatibility for darwin-x86_64 The `mkShell` override was necessary to ensure compatibility with the newer macOS SDK (version 11.0) for x86_64. The default SDK (10.12) was causing build failures because of the missing libs and frameworks. OverrideSDK creates a mapping from the default SDK in all package categories to the requested SDK (11.0).
44 lines
1.5 KiB
Nix
44 lines
1.5 KiB
Nix
{ config ? {}
|
|
, pkgs ? import ./pkgs.nix { inherit config; } }:
|
|
|
|
let
|
|
inherit (pkgs) lib stdenv callPackage;
|
|
/* No Android SDK for Darwin aarch64. */
|
|
isMacM1 = stdenv.isDarwin && stdenv.isAarch64;
|
|
|
|
/* Lock requires Xcode verison. */
|
|
xcodeWrapper = callPackage ./pkgs/xcodeenv/compose-xcodewrapper.nix { } {
|
|
versions = ["14.3" "15.1" "15.2" "15.3" "15.4"];
|
|
};
|
|
|
|
/* Gomobile also needs the Xcode wrapper. */
|
|
gomobileMod = pkgs.gomobile.override {
|
|
inherit xcodeWrapper;
|
|
withAndroidPkgs = !isMacM1;
|
|
};
|
|
/* Override the default SDK to enable darwin-x86_64 builds */
|
|
appleSdk11Stdenv = pkgs.overrideSDK pkgs.stdenv "11.0";
|
|
sdk11mkShell = pkgs.mkShell.override { stdenv = appleSdk11Stdenv; };
|
|
mkShell = if stdenv.isDarwin then sdk11mkShell else pkgs.mkShell;
|
|
|
|
in mkShell {
|
|
name = "status-go-shell";
|
|
|
|
buildInputs = with pkgs; [
|
|
git jq which
|
|
go golangci-lint go-junit-report gopls go-bindata gomobileMod codecov-cli go-generate-fast
|
|
mockgen protobuf3_20 protoc-gen-go gotestsum go-modvendor openjdk cc-test-reporter
|
|
] ++ lib.optionals (stdenv.isDarwin) [ xcodeWrapper ];
|
|
|
|
shellHook = lib.optionalString (!isMacM1) ''
|
|
ANDROID_HOME=${pkgs.androidPkgs.androidsdk}/libexec/android-sdk
|
|
ANDROID_NDK=$ANDROID_HOME/ndk-bundle
|
|
ANDROID_SDK_ROOT=$ANDROID_HOME
|
|
ANDROID_NDK_HOME=$ANDROID_NDK
|
|
'';
|
|
# Sandbox causes Xcode issues on MacOS. Requires sandbox=relaxed.
|
|
# https://github.com/status-im/status-mobile/pull/13912
|
|
__noChroot = stdenv.isDarwin;
|
|
}
|
|
|