mirror of
https://github.com/status-im/status-go.git
synced 2025-01-14 00:36:40 +00:00
e40cbfc28f
Summary ======= - [x] Changes endpoint ActivityCenterNotificationsBy to support fetching multiple types of notification in a single query. - [x] Adds endpoint UnreadAndAcceptedActivityCenterNotificationsCount to allow the mobile client to fetch the count of unread & accepted notifications. - [x] Add `golangci-lint` to Nix shell. This was possible since PR https://github.com/status-im/status-go/pull/3087 was merged. Notes ===== - If you'd like to understand why these changes are needed, please see the mobile PR https://github.com/status-im/status-mobile/pull/14785, or issue https://github.com/status-im/status-mobile/issues/14712 - All changes should be completely backwards compatible, and there should be no impact for the desktop app. - The mobile client has been already tested using this branch.
57 lines
1.7 KiB
Nix
57 lines
1.7 KiB
Nix
{
|
|
/* This should match Nixpkgs commit in status-mobile. */
|
|
source ? builtins.fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/579238da5f431b7833a9f0681663900aaf0dd1e8.zip";
|
|
sha256 = "sha256:0a77c8fq4145k0zdmsda9cmhfw84ipf9nhvvn0givzhza1500g3h";
|
|
},
|
|
pkgs ? import (source){
|
|
config = {
|
|
allowUnfree = true;
|
|
android_sdk.accept_license = true;
|
|
};
|
|
overlays = [
|
|
(self: super: {
|
|
androidPkgs = pkgs.androidenv.composeAndroidPackages {
|
|
toolsVersion = "26.1.1";
|
|
platformToolsVersion = "33.0.2";
|
|
buildToolsVersions = [ "31.0.0" ];
|
|
platformVersions = [ "31" ];
|
|
cmakeVersions = [ "3.18.1" ];
|
|
ndkVersion = "22.1.7171670";
|
|
includeNDK = true;
|
|
includeExtras = [
|
|
"extras;android;m2repository"
|
|
"extras;google;m2repository"
|
|
];
|
|
};
|
|
})
|
|
];
|
|
}
|
|
}:
|
|
|
|
pkgs.mkShell {
|
|
name = "status-go-shell";
|
|
|
|
buildInputs = with pkgs; [
|
|
git jq which
|
|
go_1_18 golangci-lint gopls go-bindata
|
|
mockgen protobuf3_17 protoc-gen-go
|
|
(gomobile.override { xcodeWrapperArgs = { version = "13.4.1"; }; })
|
|
] ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
|
|
(xcodeenv.composeXcodeWrapper { version = "13.4.1"; })
|
|
];
|
|
|
|
shellHook = let
|
|
androidSdk = pkgs.androidPkgs.androidsdk;
|
|
in ''
|
|
ANDROID_HOME=${androidSdk}/libexec/android-sdk
|
|
ANDROID_SDK_ROOT=$ANDROID_HOME
|
|
ANDROID_NDK=${androidSdk}/libexec/android-sdk/ndk-bundle
|
|
ANDROID_NDK_HOME=$ANDROID_NDK
|
|
'';
|
|
|
|
# Sandbox causes Xcode issues on MacOS. Requires sandbox=relaxed.
|
|
# https://github.com/status-im/status-mobile/pull/13912
|
|
__noChroot = pkgs.stdenv.isDarwin;
|
|
}
|