mirror of
https://github.com/status-im/status-desktop.git
synced 2025-02-28 06:21:11 +00:00
b92974ffff
- Added counter in showcase header. - Added placeholder when limit reached and section expanded. - Added placeholder when limit reached and section collapsed. - Added green animation when section collapsed and element added. - Disabled showcase delegate context menu when limit reached. - Dynamic tooltip offset center added. - Added model changes tracker to track the in showcase count. Closes #13507
63 lines
1.6 KiB
QML
63 lines
1.6 KiB
QML
import QtQuick 2.15
|
|
|
|
import StatusQ.Controls 0.1
|
|
|
|
Item {
|
|
id: root
|
|
property string aliasedObjectName
|
|
property string text
|
|
property string icon
|
|
property alias tooltipText: tooltip.text
|
|
property int buttonType: DisabledTooltipButton.Normal
|
|
property bool interactive: true
|
|
property Component buttonComponent: buttonType === DisabledTooltipButton.Normal ? normalButton : flatButton
|
|
|
|
signal clicked()
|
|
|
|
enum Type {
|
|
Normal, // 0
|
|
Flat // 1
|
|
}
|
|
|
|
implicitWidth: !!buttonLoader.item ? buttonLoader.item.width : 0
|
|
implicitHeight: !!buttonLoader.item ? buttonLoader.item.height : 0
|
|
|
|
Loader {
|
|
id: buttonLoader
|
|
anchors.centerIn: parent
|
|
sourceComponent: buttonComponent
|
|
active: root.visible
|
|
}
|
|
HoverHandler {
|
|
id: hoverHandler
|
|
enabled: !root.interactive
|
|
cursorShape: Qt.PointingHandCursor
|
|
}
|
|
StatusToolTip {
|
|
id: tooltip
|
|
visible: hoverHandler.hovered && !!text
|
|
offset: -(tooltip.x + tooltip.width/2 - root.width/2)
|
|
}
|
|
|
|
Component{
|
|
id: flatButton
|
|
StatusFlatButton {
|
|
objectName: root.aliasedObjectName
|
|
icon.name: root.icon
|
|
text: root.text
|
|
enabled: root.interactive
|
|
onClicked: root.clicked()
|
|
}
|
|
}
|
|
Component{
|
|
id: normalButton
|
|
StatusButton {
|
|
objectName: root.aliasedObjectName
|
|
icon.name: root.icon
|
|
text: root.text
|
|
enabled: root.interactive
|
|
onClicked: root.clicked()
|
|
}
|
|
}
|
|
}
|