mirror of
https://github.com/status-im/status-desktop.git
synced 2025-02-23 03:58:49 +00:00
3705249e40
- implement the basic Onboarding UI skeleton and the Create Profile flows - adjust the PasswordView and EnterSeedPhrase views to the latest design - add the main OnboardingLayout and StatusPinInput pages to Storybook - change terminology app-wide: "Seed phrase" -> "Recovery phrase" - implement the Login flows (seed, sync, keycard) - amend the keycard flow sequences with separate (non) empty page Fixes #16719 Fixes #16742 Fixes #16743
100 lines
3.4 KiB
QML
100 lines
3.4 KiB
QML
import QtQuick 2.15
|
||
import QtQuick.Controls 2.15
|
||
import QtQuick.Layouts 1.15
|
||
|
||
import StatusQ.Core 0.1
|
||
import StatusQ.Components 0.1
|
||
import StatusQ.Controls 0.1
|
||
import StatusQ.Core.Theme 0.1
|
||
|
||
OnboardingPage {
|
||
id: root
|
||
|
||
signal backupSeedphraseContinue()
|
||
|
||
pageClassName: "BackupSeedphraseAcks"
|
||
|
||
contentItem: Item {
|
||
ColumnLayout {
|
||
anchors.centerIn: parent
|
||
width: Math.min(440, root.availableWidth)
|
||
spacing: Theme.xlPadding
|
||
|
||
StatusBaseText {
|
||
Layout.fillWidth: true
|
||
text: qsTr("Backup your recovery phrase")
|
||
font.pixelSize: 22
|
||
font.bold: true
|
||
wrapMode: Text.WordWrap
|
||
horizontalAlignment: Text.AlignHCenter
|
||
}
|
||
Frame {
|
||
Layout.fillWidth: true
|
||
padding: 12
|
||
background: Rectangle {
|
||
color: Theme.palette.dangerColor3
|
||
radius: Theme.radius
|
||
}
|
||
contentItem: StatusBaseText {
|
||
text: qsTr("Store your recovery phrase in a secure location so you never lose access to your funds.")
|
||
color: Theme.palette.dangerColor1
|
||
wrapMode: Text.WordWrap
|
||
horizontalAlignment: Qt.AlignHCenter
|
||
lineHeightMode: Text.FixedHeight
|
||
lineHeight: 22
|
||
}
|
||
}
|
||
StatusBaseText {
|
||
Layout.fillWidth: true
|
||
wrapMode: Text.WordWrap
|
||
font.weight: Font.DemiBold
|
||
text: qsTr("Backup checklist:")
|
||
}
|
||
Frame {
|
||
Layout.fillWidth: true
|
||
Layout.topMargin: -20
|
||
padding: 20
|
||
background: Rectangle {
|
||
color: "transparent"
|
||
radius: 12
|
||
border.width: 1
|
||
border.color: Theme.palette.baseColor2
|
||
}
|
||
contentItem: ColumnLayout {
|
||
StatusCheckBox {
|
||
objectName: "ack1"
|
||
Layout.fillWidth: true
|
||
id: ack1
|
||
text: qsTr("I have a pen and paper")
|
||
}
|
||
StatusCheckBox {
|
||
objectName: "ack2"
|
||
Layout.fillWidth: true
|
||
id: ack2
|
||
text: qsTr("I am ready to write down my recovery phrase")
|
||
}
|
||
StatusCheckBox {
|
||
objectName: "ack3"
|
||
Layout.fillWidth: true
|
||
id: ack3
|
||
text: qsTr("I know where I’ll store it")
|
||
}
|
||
StatusCheckBox {
|
||
objectName: "ack4"
|
||
Layout.fillWidth: true
|
||
id: ack4
|
||
text: qsTr("I know I can only reveal it once")
|
||
}
|
||
}
|
||
}
|
||
StatusButton {
|
||
objectName: "btnContinue"
|
||
Layout.alignment: Qt.AlignHCenter
|
||
text: qsTr("Continue")
|
||
enabled: ack1.checked && ack2.checked && ack3.checked && ack4.checked
|
||
onClicked: root.backupSeedphraseContinue()
|
||
}
|
||
}
|
||
}
|
||
}
|