status-im/status-desktop
2
0
Fork 0
mirror of https://github.com/status-im/status-desktop.git synced 2025-01-22 04:21:44 +00:00
Code Issues Projects Releases Wiki Activity

fix: Adding Beta user agreement

Browse Source
This commit is contained in:
Alex Jbanca 2023-06-14 22:06:13 +03:00 committed by Alex Jbanca
parent 65b5d411e9
commit c4e9f8dba0
7 changed files with 176 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

4
storybook/PagesModel.qml
View File

@ -217,6 +217,10 @@ ListModel {
title: "SendModal"
section: "Popups"
}
ListElement {
title: "UserAgreementPopup"
section: "Popups"
}
ListElement {
title: "MembersSelector"
section: "Components"

3
storybook/figma.json
View File

@ -212,5 +212,8 @@
"https://www.figma.com/file/17fc13UBFvInrLgNUKJJg5/Kuba%E2%8E%9CDesktop?type=design&node-id=29528%3A588403&t=GUxMZEWcfRO7pXJb-1",
"https://www.figma.com/file/17fc13UBFvInrLgNUKJJg5/Kuba%E2%8E%9CDesktop?type=design&node-id=29528%3A588563&t=GUxMZEWcfRO7pXJb-1",
"https://www.figma.com/file/17fc13UBFvInrLgNUKJJg5/Kuba%E2%8E%9CDesktop?type=design&node-id=29528%3A587660&t=GUxMZEWcfRO7pXJb-1"
],
"UserAgreementPopup": [
"https://www.figma.com/file/17fc13UBFvInrLgNUKJJg5/Kuba⎜Desktop?type=design&node-id=31450-560694&t=Q4MOViPCoHsTjhs6-0"
]
}

34
storybook/pages/UserAgreementPopupPage.qml Normal file
View File

@ -0,0 +1,34 @@
import QtQuick 2.15
import QtQuick.Controls 2.15
import shared.popups 1.0
import Storybook 1.0
SplitView {
orientation: Qt.Vertical
Item {
SplitView.fillWidth: true
SplitView.fillHeight: true
PopupBackground {
anchors.fill: parent
}
Button {
anchors.centerIn: parent
text: "Reopen"
onClicked: popup.open()
}
}
UserAgreementPopup {
id: popup
anchors.centerIn: parent
modal: false
visible: true
}
}

9
ui/app/mainui/AppMain.qml
View File

@ -1420,4 +1420,13 @@ Item {
width: appMain.width
height: appMain.height
}
Loader {
id: userAgreementLoader
active: production && !localAppSettings.testEnvironment
sourceComponent: UserAgreementPopup {
visible: appMain.visible
onClosed: userAgreementLoader.active = false
}
}
}

124
ui/imports/shared/popups/UserAgreementPopup.qml Normal file
View File

@ -0,0 +1,124 @@
import QtQuick 2.15
import QtQuick.Controls 2.15
import QtQuick.Layouts 1.15
import StatusQ.Core 0.1
import StatusQ.Controls 0.1
import StatusQ.Popups 0.1
import StatusQ.Popups.Dialog 0.1
import StatusQ.Components 0.1
import StatusQ.Core.Theme 0.1
import utils 1.0
StatusModal {
id: root
width: 640
headerSettings.title: qsTr("Welcome to Status Desktop Beta")
hasCloseButton: false
closePolicy: Popup.NoAutoClose
component Paragraph: StatusBaseText {
font.pixelSize: 15
lineHeightMode: Text.FixedHeight
lineHeight: 22
visible: !!text
wrapMode: Text.Wrap
}
component AgreementSection: ColumnLayout {
property alias title: titleItem.text
property alias body: bodyItem.text
spacing: 12
Paragraph {
id: titleItem
Layout.fillWidth: true
Layout.fillHeight: true
font.weight: Font.DemiBold
}
Paragraph {
id: bodyItem
Layout.fillWidth: true
Layout.fillHeight: true
}
}
StatusScrollView {
id: scrollView
anchors.fill: parent
contentWidth: availableWidth
ColumnLayout {
id: layout
width: scrollView.availableWidth
spacing: 22
StatusRoundedImage {
id: statusRoundedImage
objectName: "headerImage"
Layout.preferredWidth: 64
Layout.preferredHeight: 64
Layout.alignment: Qt.AlignHCenter
image.source: Style.png("status-logo")
image.mipmap: true
}
AgreementSection {
title: qsTr("Warning - Status desktop is currently in Beta")
body: qsTr("• The Wallet is not yet safe or secure to use
• Do not use real funds in the Wallet
• Do not use accounts that contain tokens of value in the Wallet")
}
AgreementSection {
title: qsTr("Also be aware")
body: qsTr("• Status Desktop is incompatible with Status Mobile versions 1.x
• This version of Status may break or stop working without warning
• Communities created with this version may be broken by future releases
• Status desktop currently consumes large amounts of bandwidth")
}
AgreementSection {
body: qsTr("We are working to fix all these issues ASAP, ahead of Status Desktop’s 1.0 release!")
}
StatusDialogDivider {
Layout.fillWidth: true
}
AgreementSection {
body: qsTr("I confirm that...")
}
StatusCheckBox {
id: agreeToUse
Layout.fillWidth: true
Layout.topMargin: -10 //reduced margin by design
contentItem: Paragraph {
text: qsTr("I’ve read the above and understand that Status Desktop is Beta software")
leftPadding: readyToUse.indicator.width + readyToUse.spacing
}
}
StatusCheckBox {
id: readyToUse
Layout.fillWidth: true
Layout.topMargin: -10 //reduced margin by design
Layout.bottomMargin: layout.spacing
contentItem: Paragraph {
text: qsTr("I’m ready to use Status Desktop Beta")
leftPadding: readyToUse.indicator.width + readyToUse.spacing
}
}
}
}
rightButtons: [
StatusButton {
text: qsTr("I’m ready to use Status Desktop Beta")
enabled: agreeToUse.checked && readyToUse.checked
onClicked: root.close()
}
]
}

1
ui/imports/shared/popups/qmldir
View File

@ -27,3 +27,4 @@ GetSyncCodeInstructionsPopup 1.0 GetSyncCodeInstructionsPopup.qml
NoPermissionsToJoinPopup 1.0 NoPermissionsToJoinPopup.qml
RemoveAccountConfirmationPopup 1.0 RemoveAccountConfirmationPopup.qml
DeleteMessageConfirmationPopup 1.0 DeleteMessageConfirmationPopup.qml
UserAgreementPopup 1.0 UserAgreementPopup.qml

1
ui/main.qml
View File

@ -323,6 +323,7 @@ StatusWindow {
id: app
AppMain {
sysPalette: systemPalette
visible: !appLoadingAnimation.active
}
}