mirror of
https://github.com/status-im/status-app.git
synced 2026-08-27 07:01:14 +00:00
Alex Jbanca
754276d853
A wallet section activation built everything it would ever need before it showed anything: both panels inline, both detail views, every row of two lists synchronously, and a set of subtrees that exist for cases that almost never occur. This reorders that around a single rule - build what is on screen first, build the rest in the incubation controller's metered bites, and build the rest of the rest only when something asks for it. Lists fill preemptibly. A ListView refill is one uninterruptible call inside the window's polish phase, and QQuickItemView creates visible delegates with AsynchronousIfNested - so a list first laid out after its enclosing Loader is already Ready builds every visible row synchronously. On a warm load that was one 34.7ms GUI-thread block against a 3.2ms budget for the assets list, and 8.7-13.5ms of post-content polish across both lists. The assets and accounts delegates become TokenDelegateShell and WalletAccountDelegateShell: an Item carrying the row's geometry and its placeholder tiles, with the real row behind a nested asynchronous Loader. The refill builds shells; the rows incubate afterwards. Row height is the shell's, not the content's. StatusListItem.implicitHeight is Math.max(64, titleArea.height + 16), and both a token row and an account row resolve to that 64px floor, which is what placeholderHeight is. tst_TokenDelegateShell and tst_WalletAccountDelegateShell gate the two staying equal, so a change that makes a row taller fails a test rather than moving contentHeight and the scroll position mid-fill. Each placeholder mirrors the skeleton the per-tab loader showed a moment earlier, so the two loading states read as one handoff. Subtrees built for the exceptional case are latched off. The token row's two warning buttons, the asset detail's four chain-tag warning buttons, its header community tag and its "Minted by" tile were all built unconditionally and merely hidden. Each now sits behind the condition that used to drive `visible`. AssetsDetailsHeader loses its `communityTag` alias, which existed only so callers could reach in and set the tag's contents; it takes communityName/communityImage and builds the tag itself. The two detail views move behind async Loaders keyed on the stack index. The token to show becomes state held in `d` and bound into the view rather than assigned into it, so a second click landing mid-incubation wins without a queue-and-replay; the resets that hung off onVisibleChanged hang off onActiveChanged, which fires on the same edges. Panels build in the order the user sees them. WalletLayout declared both panels as plain object bindings, so activation built LeftTabView and the centre StackView inline and the chrome's two PanelSwapGates could not fire independently - they opened 5ms apart because both panel properties resolve when WalletLayout completes. Each panel now sits behind its own async Loader with its own readiness, the primary one first, and once a skeleton is on screen with no panel switch running the primary panel is built synchronously: the pacing exists to protect section-switch animations, and here the only thing a synchronous block could stutter is the skeleton it replaces. Wrapping the panels in Loaders exposed three geometry defects. A Loader reports its item's implicit size as its own, so the centre StackView's content width propagated into the chrome and pushed the panel past the right edge on a narrow screen; the loaders are bound to the chrome's geometry for the unparented phase, the stack no longer anchors to its loader, and the side inset moves onto the content where it belongs. Panel geometry is coalesced across a rotation. A device rotation walks the window through nine sizes over ~430ms and LayoutItemProxy forwarded every one to the section's panels - a full relayout of a populated subtree each time - and parked a panel at a degenerate box for ~148ms on the portrait/landscape handoff. SectionPanelSlot replaces the panel proxies in both sub-layouts and publishes the box each slot will give its panel, which is also what a section building panels outside the tree needs: the centre slot cannot be guessed, as it is short by the header and footer and narrow by the left column in landscape. Wallet and chat both pre-size their incubating panels to it. Two fixes fall out of that work. BaseProxyPanel looked its SwipeView page up at a fixed implicitIndex, but SwipeView indices close up as pages come and go, so hiding the right panel with no left panel present silently left its page in the view, still swipeable; it now looks the page up by identity. SectionPanelSlot also has to be listed in statusq.qrc - without it the type is absent from the binary's resources, StatusSectionLayout becomes unavailable and the UI process dies precompiling AppMain. Measured on a whale profile, Release, arms alternated between rounds: warm t_first_asset_row 119-159ms -> 51-74ms warm max_stall_ms 31.7-42.6 -> 17.2-26.3ms section ready 631ms -> 207ms visible panel promoted 609ms -> 338ms cold: skeleton shown -> visible 2272ms -> 1836ms objects_total (cold) 4602 -> 3344 (-27%) objects_settled 9569 -> 8297 (-13%) token row QObjects 326 -> 279 panel geometry distinct sizes 24 -> 5 centre, 19 -> 2 left degenerate 0x0 box written 12 occurrences -> 0 Device numbers are only comparable once the app has settled; a run taken while startup backend work is still in flight measured 925ms for a path that measures ~520ms settled. Measurements come from an offscreen storybook wallet bench that is not part of this PR; see branch `feat/storybook-wallet-loader`.
177 lines
6.2 KiB
QML
177 lines
6.2 KiB
QML
import QtQuick
|
|
import QtQuick.Controls
|
|
import QtQuick.Layouts
|
|
|
|
import utils
|
|
import shared.controls
|
|
|
|
import StatusQ
|
|
import StatusQ.Components
|
|
import StatusQ.Core.Theme
|
|
import StatusQ.Core
|
|
import StatusQ.Core.Utils as SQUtils
|
|
import StatusQ.Controls
|
|
|
|
import QtModelsToolkit
|
|
import SortFilterProxyModel
|
|
|
|
Control {
|
|
id: root
|
|
|
|
property alias primaryText: tokenName.text
|
|
property alias secondaryText: cryptoBalance.text
|
|
property alias tertiaryText: fiatBalance.text
|
|
property string communityName
|
|
property string communityImage
|
|
property var balances
|
|
property int decimals
|
|
property var networksModel
|
|
property bool isLoading: false
|
|
property string errorTooltipText
|
|
property string address
|
|
property StatusAssetSettings asset: StatusAssetSettings {
|
|
width: 25
|
|
height: 25
|
|
}
|
|
property var formatBalance: function(balance){}
|
|
|
|
topPadding: Theme.padding
|
|
|
|
// One Component shared by every chain tag: the button used to be built for
|
|
// each of them and hidden, and it carries a StatusToolTip.
|
|
Component {
|
|
id: chainErrorButton
|
|
|
|
StatusFlatRoundButton {
|
|
width: 14
|
|
height: 14
|
|
icon.width: 14
|
|
icon.height: 14
|
|
icon.name: "tiny/warning"
|
|
icon.color: Theme.palette.dangerColor1
|
|
tooltip.text: root.errorTooltipText
|
|
}
|
|
}
|
|
|
|
contentItem: ColumnLayout {
|
|
id: mainLayout
|
|
spacing: 4
|
|
readonly property bool isOverflowing: root.width < tokenNameAndIcon.width + communityAndBalances.width + fiatBalanceLayout.width
|
|
|
|
RowLayout {
|
|
id: tokenNameAndIcon
|
|
Layout.fillWidth: true
|
|
spacing: 8
|
|
StatusTextWithLoadingState {
|
|
id: tokenName
|
|
Layout.alignment: Qt.AlignHCenter
|
|
Layout.maximumWidth: root.width-root.asset.width-8
|
|
font.pixelSize: Theme.fontSize(28)
|
|
font.bold: true
|
|
lineHeight: 38
|
|
lineHeightMode: Text.FixedHeight
|
|
elide: Text.ElideRight
|
|
customColor: Theme.palette.directColor1
|
|
loading: root.isLoading
|
|
}
|
|
StatusSmartIdenticon {
|
|
Layout.preferredWidth: root.asset.width
|
|
Layout.alignment: Qt.AlignHCenter
|
|
asset: root.asset
|
|
loading: root.isLoading
|
|
}
|
|
}
|
|
|
|
GridLayout {
|
|
Layout.fillWidth: true
|
|
rowSpacing: Theme.halfPadding
|
|
columnSpacing: Theme.halfPadding
|
|
flow: mainLayout.isOverflowing ? GridLayout.TopToBottom: GridLayout.LeftToRight
|
|
|
|
RowLayout {
|
|
id: fiatBalanceLayout
|
|
Layout.fillWidth: true
|
|
spacing: Theme.halfPadding
|
|
StatusTextWithLoadingState {
|
|
id: cryptoBalance
|
|
Layout.alignment: Qt.AlignHCenter
|
|
font.pixelSize: Theme.fontSize(28)
|
|
font.bold: true
|
|
lineHeight: 38
|
|
lineHeightMode: Text.FixedHeight
|
|
customColor: Theme.palette.baseColor1
|
|
loading: root.isLoading
|
|
}
|
|
StatusTextWithLoadingState {
|
|
id: fiatBalance
|
|
Layout.alignment: Qt.AlignBottom
|
|
Layout.bottomMargin: 2
|
|
font.pixelSize: Theme.primaryTextFontSize
|
|
lineHeight: 22
|
|
lineHeightMode: Text.FixedHeight
|
|
customColor: Theme.palette.baseColor1
|
|
loading: root.isLoading
|
|
}
|
|
}
|
|
|
|
Item {
|
|
id: filler
|
|
Layout.fillWidth: true
|
|
}
|
|
|
|
RowLayout {
|
|
id: communityAndBalances
|
|
Layout.fillWidth: true
|
|
spacing: Theme.halfPadding
|
|
Loader {
|
|
active: !!root.communityName || !!root.communityImage
|
|
visible: active
|
|
sourceComponent: InformationTag {
|
|
objectName: "assetsDetailsHeaderCommunityTag"
|
|
tagPrimaryLabel.text: root.communityName
|
|
asset.name: root.communityImage
|
|
asset.isImage: true
|
|
}
|
|
}
|
|
Repeater {
|
|
id: chainRepeater
|
|
Layout.alignment: Qt.AlignRight
|
|
model: root.networksModel
|
|
delegate: InformationTag {
|
|
objectName: "assetsDetailsHeaderChainTag_" + model.chainId
|
|
|
|
readonly property double aggregatedbalance: balancesAggregator.value/(10 ** root.decimals)
|
|
SortFilterProxyModel {
|
|
id: filteredBalances
|
|
sourceModel: root.balances
|
|
filters: [
|
|
ValueFilter {
|
|
roleName: "chainId"
|
|
value: model.chainId
|
|
},
|
|
ValueFilter {
|
|
roleName: "account"
|
|
value: root.address.toLowerCase()
|
|
enabled: !!root.address
|
|
}
|
|
]
|
|
}
|
|
SumAggregator {
|
|
id: balancesAggregator
|
|
model: filteredBalances
|
|
roleName: "balance"
|
|
}
|
|
tagPrimaryLabel.text: root.formatBalance(aggregatedbalance)
|
|
tagPrimaryLabel.color: Theme.palette.directColor1
|
|
asset.name: Assets.svg(model.iconUrl)
|
|
asset.isImage: true
|
|
loading: root.isLoading
|
|
visible: balancesAggregator.value > 0
|
|
rightComponent: !!root.errorTooltipText ? chainErrorButton : null
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|