added version file

CMakeLists.txt

@@ -7,11 +7,6 @@ option(WITH_FREEDESKTOP_FRONTEND "Build the freedesktop frontend" OFF)
 option(WITH_GROWL_BACKEND "Build the Growl backend" ON)
 #######################################################################
 
-set(SNORE_VERSION_MAJOR 0)
-set(SNORE_VERSION_MINOR 3)
-set(SNORE_VERSION_SUFFIX pre)
-add_definitions(-DSNORE_VERSION_MAJOR="${SNORE_VERSION_MAJOR}" -DSNORE_VERSION_MINOR="${SNORE_VERSION_MINOR}" -DSNORE_VERSION_SUFFIX="${SNORE_VERSION_SUFFIX}") 
-######################################################################
 
 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 

cmake/modules/GetGitRevisionDescription.cmake

@@ -0,0 +1,104 @@
+# - Returns a version string from Git
+#
+# These functions force a re-configure on each git commit so that you can
+# trust the values of the variables in your build system.
+#
+#  get_git_head_revision(<refspecvar> <hashvar> [<additonal arguments to git describe> ...])
+#
+# Returns the refspec and sha hash of the current head revision
+#
+#  git_describe(<var> [<additonal arguments to git describe> ...])
+#
+# Returns the results of git describe on the source tree, and adjusting
+# the output so that it tests false if an error occurs.
+#
+#  git_get_exact_tag(<var> [<additonal arguments to git describe> ...])
+#
+# Returns the results of git describe --exact-match on the source tree,
+# and adjusting the output so that it tests false if there was no exact
+# matching tag.
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+if(__get_git_revision_description)
+	return()
+endif()
+set(__get_git_revision_description YES)
+
+# We must run the following at "include" time, not at function call time,
+# to find the path to this module rather than the path to a calling list file
+get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+function(get_git_head_revision _refspecvar _hashvar)
+	set(GIT_DIR "${CMAKE_SOURCE_DIR}/.git")
+	if(NOT EXISTS "${GIT_DIR}")
+		# not in git
+		set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+		set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+	set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
+	if(NOT EXISTS "${GIT_DATA}")
+		file(MAKE_DIRECTORY "${GIT_DATA}")
+	endif()
+	set(HEAD_FILE "${GIT_DATA}/HEAD")
+	configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
+
+	configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in" "${GIT_DATA}/grabRef.cmake" @ONLY)
+	include("${GIT_DATA}/grabRef.cmake")
+
+	set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
+	set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
+endfunction()
+
+function(git_describe _var)
+	if(NOT GIT_FOUND)
+		find_package(Git QUIET)
+	endif()
+	get_git_head_revision(refspec hash)
+	if(NOT GIT_FOUND)
+		set(${_var} "GIT-NOTFOUND"  PARENT_SCOPE)
+		return()
+	endif()
+	if(NOT hash)
+		set(${_var} "HEAD-HASH-NOTFOUND"  PARENT_SCOPE)
+		return()
+	endif()
+
+	# TODO sanitize
+	#if((${ARGN}" MATCHES "&&") OR
+	#	(ARGN MATCHES "||") OR
+	#	(ARGN MATCHES "\\;"))
+	#	message("Please report the following error to the project!")
+	#	message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
+	#endif()
+
+	#message(STATUS "Arguments to execute_process: ${ARGN}")
+
+	execute_process(COMMAND "${GIT_EXECUTABLE}" describe ${hash} ${ARGN}
+		WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
+		RESULT_VARIABLE res
+		OUTPUT_VARIABLE out
+		ERROR_QUIET
+		OUTPUT_STRIP_TRAILING_WHITESPACE)
+	if(NOT res EQUAL 0)
+		set(out "${out}-${res}-NOTFOUND")
+	endif()
+
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_get_exact_tag _var)
+	git_describe(out --exact-match ${ARGN})
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()

cmake/modules/GetGitRevisionDescription.cmake.in

@@ -0,0 +1,38 @@
+# 
+# Internal file for GetGitRevisionDescription.cmake
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+set(HEAD_HASH)
+
+file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
+
+string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
+if(HEAD_CONTENTS MATCHES "ref")
+	# named branch
+	string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
+	if(EXISTS "@GIT_DIR@/${HEAD_REF}")
+	configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+	elseif(EXISTS "@GIT_DIR@/logs/${HEAD_REF}")
+		configure_file("@GIT_DIR@/logs/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+		set(HEAD_HASH "${HEAD_REF}")
+	endif()
+else()
+	# detached HEAD
+	configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
+endif()
+
+if(NOT HEAD_HASH)
+file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
+string(STRIP "${HEAD_HASH}" HEAD_HASH)
+endif()

src/core/CMakeLists.txt

@@ -1,4 +1,15 @@
 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
+
+include(GetGitRevisionDescription)
+
+
+set(SNORE_VERSION_MAJOR 0)
+set(SNORE_VERSION_MINOR 3)
+set(SNORE_VERSION_SUFFIX pre)
+get_git_head_revision(GIT_REFSPEC SNORE_REVISION)
+
+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/version.cpp.in" "${CMAKE_CURRENT_BINARY_DIR}/version.cpp" @ONLY)
+
 add_subdirectory(notification)
 
 set ( SnoreNotify_SRCS ${SnoreNotify_SRCS}
@@ -6,6 +17,7 @@ set ( SnoreNotify_SRCS ${SnoreNotify_SRCS}
         application.cpp
         interface.cpp
         trayiconnotifer.cpp
+		${CMAKE_CURRENT_BINARY_DIR}/version.cpp
         )
 
 set ( SnoreNotify_HDR ${SnoreNotify_HDR}
@@ -13,6 +25,7 @@ set ( SnoreNotify_HDR ${SnoreNotify_HDR}
         application.h
         interface.h
         snore_exports.h
+		version.h
         )
 
 automoc4_add_library( snorecore  SHARED ${SnoreNotify_SRCS})

src/core/snoreserver.cpp

@@ -17,6 +17,7 @@
 #include "snoreserver.h"
 #include "notification/notification.h"
 #include "trayiconnotifer.h"
+#include "version.h"
 
 #include <iostream>
 
@@ -28,7 +29,7 @@
 namespace Snore{
 
 QString const SnoreServer::version(){
-    return QString(SNORE_VERSION_MAJOR).append(".").append(SNORE_VERSION_MINOR).append(SNORE_VERSION_SUFFIX);
+    return QString().append(Version::major()).append(".").append(Version::minor()).append(Version::suffix());
 }
 
 QString const SnoreServer::snoreTMP(){

src/core/version.cpp.in

@@ -0,0 +1,24 @@
+#include "version.h"
+#define SNORE_VERSION_MAJOR "@SNORE_VERSION_MAJOR@"
+#define SNORE_VERSION_MINOR "@SNORE_VERSION_MINOR@"
+#define SNORE_VERSION_SUFFIX "@SNORE_VERSION_SUFFIX@"
+#define SNORE_REVISION "@SNORE_REVISION@"
+
+namespace Snore{
+
+const QString Version::major(){
+	return QString(SNORE_VERSION_MAJOR);
+}
+
+const QString Version::minor(){
+	return QString(SNORE_VERSION_MINOR);
+}
+const QString Version::suffix(){
+	return QString(SNORE_VERSION_SUFFIX);
+}
+
+const QString Version::revision(){
+	return QString(SNORE_REVISION);
+}
+
+}

src/core/version.h

@@ -0,0 +1,23 @@
+#ifndef VERSION_H
+#define VERSION_H
+
+#include "snore_exports.h"
+
+#include <QString>
+
+namespace Snore{
+
+class SNORE_EXPORT Version{
+public:
+static const QString major();
+
+static const QString minor();
+
+static const QString suffix();
+
+static const QString revision();
+
+};
+
+}
+#endif