mirror of
https://github.com/status-im/react-native.git
synced 2025-02-25 15:45:32 +00:00
8206e841d1
Summary: Don't ask. Really, all those descriptions from official docs like below are useless: * `__bridge_transfer` Moves a Core Foundation pointer to Objective-C with transfer of the ownership to ARC. * `__bridge` Transfers a pointer between Objective-C and Core Foundation with no transfer of ownership All that is totally confusing and useless. At the end of the day, we only have to think about which additional `CFRetain` and `CFRelease` ARC will add or will not add for our pointers. So, following official docs recommendation, we would like to add `__bridge_transfer` because of course, we do want to ARC managing the variable after we introduced it to ARC here. But we also want to have shared ownership of this. That's the key. If we use `__bridge_transfer` ARC will assume that this variable already retained once (because it exists) and will call CFRelease at the end of the scope. Right before that when we pass this variable down to call stack ARC will retain and then manage the variable according to the rest of the code. But still, from this point, we will have zero-balanced reference counter; the owning by `shared_ptr` bump is already compensated with `CFRelease` at the end of the scope. As soon as the rest of the code release the object, it will be incorrectly deallocated. So, instead of using `__bridge_transfer` we have to use `__bridge`. That will indicate that *in this block* ARC does not manage the reference counter of the variable (which is kinda true because having `shared_ptr` inside the block already retains that) and will not add `CFRelease` at the end of the block. Reviewed By: mdvacca Differential Revision: D10054241 fbshipit-source-id: 6e82c5270fe5d53f1ed68e167b94f70dc4367a9f
114 lines
3.7 KiB
Plaintext
114 lines
3.7 KiB
Plaintext
/**
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTImageComponentView.h"
|
|
|
|
#import <fabric/components/image/ImageEventEmitter.h>
|
|
#import <fabric/components/image/ImageLocalData.h>
|
|
#import <fabric/components/image/ImageProps.h>
|
|
#import <fabric/imagemanager/ImageRequest.h>
|
|
#import <fabric/imagemanager/ImageResponse.h>
|
|
#import <fabric/imagemanager/RCTImagePrimitivesConversions.h>
|
|
|
|
#import "RCTConversions.h"
|
|
#import "MainQueueExecutor.h"
|
|
|
|
using namespace facebook::react;
|
|
|
|
@implementation RCTImageComponentView {
|
|
UIImageView *_imageView;
|
|
SharedImageLocalData _imageLocalData;
|
|
}
|
|
|
|
- (instancetype)initWithFrame:(CGRect)frame
|
|
{
|
|
if (self = [super initWithFrame:frame]) {
|
|
static const auto defaultProps = std::make_shared<const ImageProps>();
|
|
_props = defaultProps;
|
|
|
|
_imageView = [[UIImageView alloc] initWithFrame:self.bounds];
|
|
_imageView.clipsToBounds = YES;
|
|
|
|
_imageView.contentMode = (UIViewContentMode)RCTResizeModeFromImageResizeMode(defaultProps->resizeMode);
|
|
|
|
self.contentView = _imageView;
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
#pragma mark - RCTComponentViewProtocol
|
|
|
|
- (void)updateProps:(SharedProps)props oldProps:(SharedProps)oldProps
|
|
{
|
|
const auto &oldImageProps = *std::static_pointer_cast<const ImageProps>(oldProps ?: _props);
|
|
const auto &newImageProps = *std::static_pointer_cast<const ImageProps>(props);
|
|
|
|
[super updateProps:props oldProps:oldProps];
|
|
|
|
// `resizeMode`
|
|
if (oldImageProps.resizeMode != newImageProps.resizeMode) {
|
|
if (newImageProps.resizeMode == ImageResizeMode::Repeat) {
|
|
// Repeat resize mode is handled by the UIImage. Use scale to fill
|
|
// so the repeated image fills the UIImageView.
|
|
_imageView.contentMode = UIViewContentModeScaleToFill;
|
|
} else {
|
|
_imageView.contentMode = (UIViewContentMode)RCTResizeModeFromImageResizeMode(newImageProps.resizeMode);
|
|
}
|
|
}
|
|
|
|
// `tintColor`
|
|
if (oldImageProps.tintColor != newImageProps.tintColor) {
|
|
_imageView.tintColor = [UIColor colorWithCGColor:newImageProps.tintColor.get()];
|
|
}
|
|
}
|
|
|
|
- (void)updateLocalData:(SharedLocalData)localData
|
|
oldLocalData:(SharedLocalData)oldLocalData
|
|
{
|
|
_imageLocalData = std::static_pointer_cast<const ImageLocalData>(localData);
|
|
assert(_imageLocalData);
|
|
auto future = _imageLocalData->getImageRequest().getResponseFuture();
|
|
future.via(&MainQueueExecutor::instance()).then([self](ImageResponse &&imageResponse) {
|
|
self.image = (__bridge UIImage *)imageResponse.getImage().get();
|
|
});
|
|
}
|
|
|
|
- (void)prepareForRecycle
|
|
{
|
|
[super prepareForRecycle];
|
|
_imageView.image = nil;
|
|
}
|
|
|
|
#pragma mark - Other
|
|
|
|
- (void)setImage:(UIImage *)image
|
|
{
|
|
const auto &imageProps = *std::static_pointer_cast<const ImageProps>(_props);
|
|
|
|
if (imageProps.tintColor) {
|
|
image = [image imageWithRenderingMode:UIImageRenderingModeAlwaysTemplate];
|
|
}
|
|
|
|
if (imageProps.resizeMode == ImageResizeMode::Repeat) {
|
|
image = [image resizableImageWithCapInsets:RCTUIEdgeInsetsFromEdgeInsets(imageProps.capInsets)
|
|
resizingMode:UIImageResizingModeTile];
|
|
} else if (imageProps.capInsets != EdgeInsets()) {
|
|
// Applying capInsets of 0 will switch the "resizingMode" of the image to "tile" which is undesired.
|
|
image = [image resizableImageWithCapInsets:RCTUIEdgeInsetsFromEdgeInsets(imageProps.capInsets)
|
|
resizingMode:UIImageResizingModeStretch];
|
|
}
|
|
|
|
_imageView.image = image;
|
|
|
|
// Apply trilinear filtering to smooth out mis-sized images.
|
|
_imageView.layer.minificationFilter = kCAFilterTrilinear;
|
|
_imageView.layer.magnificationFilter = kCAFilterTrilinear;
|
|
}
|
|
|
|
@end
|