Fabric: Introducing RCTSurfaceRegistry

Summary: Simple incapsulation of thread-safe weak set of Surface instances.

Reviewed By: mdvacca

Differential Revision: D7526409

fbshipit-source-id: 8dd789fd6148af3dacf74aac2125b022d11a0fdb

React/Fabric/RCTSurfaceRegistry.h

@@ -0,0 +1,43 @@
+/**
+ * Copyright (c) 2015-present, Facebook, Inc.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import <UIKit/UIKit.h>
+
+#import <React/RCTPrimitives.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@class RCTFabricSurface;
+
+/**
+ * Registry of Surfaces.
+ * Incapsulates storing Surface objects and quering them by root tag.
+ * All methods of the registry are thread-safe.
+ * The registry stores Surface objects as weak refereces.
+ */
+@interface RCTSurfaceRegistry : NSObject
+
+/**
+ * Adds Surface object into the registry.
+ * The registry does not retain Surface references.
+ */
+- (void)registerSurface:(RCTFabricSurface *)surface;
+
+/**
+ * Removes Surface object from the registry.
+ */
+- (void)unregisterSurface:(RCTFabricSurface *)surface;
+
+/**
+ * Returns stored Surface object by given root tag.
+ * If the registry does not have such Surface registred, returns `nil`.
+ */
+- (nullable RCTFabricSurface *)surfaceForRootTag:(ReactTag)rootTag;
+
+@end
+
+NS_ASSUME_NONNULL_END

React/Fabric/RCTSurfaceRegistry.mm

@@ -0,0 +1,52 @@
+/**
+ * Copyright (c) 2015-present, Facebook, Inc.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import "RCTSurfaceRegistry.h"
+
+#import <mutex>
+
+#import <React/RCTFabricSurface.h>
+
+@implementation RCTSurfaceRegistry {
+  std::mutex _mutex;
+  NSMapTable<id, RCTFabricSurface *> *_registry;
+}
+
+- (instancetype)init
+{
+  if (self = [super init]) {
+    _registry = [NSMapTable mapTableWithKeyOptions:NSPointerFunctionsIntegerPersonality | NSPointerFunctionsOpaqueMemory
+                                      valueOptions:NSPointerFunctionsObjectPersonality];
+  }
+
+  return self;
+}
+
+- (void)registerSurface:(RCTFabricSurface *)surface
+{
+  std::lock_guard<std::mutex> lock(_mutex);
+
+  ReactTag rootTag = surface.rootViewTag.integerValue;
+  [_registry setObject:surface forKey:(__bridge id)(void *)rootTag];
+}
+
+- (void)unregisterSurface:(RCTFabricSurface *)surface
+{
+  std::lock_guard<std::mutex> lock(_mutex);
+
+  ReactTag rootTag = surface.rootViewTag.integerValue;
+  [_registry removeObjectForKey:(__bridge id)(void *)rootTag];
+}
+
+- (RCTFabricSurface *)surfaceForRootTag:(ReactTag)rootTag
+{
+  std::lock_guard<std::mutex> lock(_mutex);
+
+  return [_registry objectForKey:(__bridge id)(void *)rootTag];
+}
+
+@end