nimbus-eth2/tests/consensus_spec/altair/test_fixture_operations_sync_aggregate.nim

# beacon_chain
# Copyright (c) 2018-2021 Status Research & Development GmbH
# Licensed and distributed under either of
#   * MIT license (license terms in the root directory or at https://opensource.org/licenses/MIT).
#   * Apache v2 license (license terms in the root directory or at https://www.apache.org/licenses/LICENSE-2.0).
# at your option. This file may not be copied, modified, or distributed except according to those terms.

{.used.}

import
  # Standard library
  os,
  # Utilities
  stew/results,
  chronicles,
  # Beacon chain internals
  ../../../beacon_chain/spec/[beaconstate, state_transition_block],
  ../../../beacon_chain/spec/datatypes/altair,
  # Test utilities
  ../../testutil,
  ../fixtures_utils,
  ../../helpers/debug_state

const OpSyncAggregateDir = SszTestsDir/const_preset/"altair"/"operations"/"sync_aggregate"/"pyspec_tests"

proc runTest(dir, identifier: string) =
  let testDir = dir / identifier

  proc `testImpl_sync_committee _ identifier`() =

    let prefix =
      if existsFile(testDir/"post.ssz_snappy"):
        "[Valid]   "
      else:
        "[Invalid] "

    test prefix & identifier:
      var
        cache = StateCache()
        preState =
          newClone(parseTest(testDir/"pre.ssz_snappy", SSZ, altair.BeaconState))

      let
        syncAggregate = parseTest(
          testDir/"sync_aggregate.ssz_snappy", SSZ, SyncAggregate)
        total_active_balance = get_total_active_balance(preState[], cache)
        done = process_sync_aggregate(
          preState[], syncAggregate, total_active_balance, cache)

      if existsFile(testDir/"post.ssz_snappy"):
        let postState =
          newClone(parseTest(testDir/"post.ssz_snappy", SSZ, altair.BeaconState))

        check:
          done.isOk()
          preState[].hash_tree_root() == postState[].hash_tree_root()
        reportDiff(preState, postState)
      else:
        check: done.isErr() # No post state = processing should fail

  `testImpl_sync_committee _ identifier`()

suite "Ethereum Foundation - Altair - Operations - Sync Aggregate" & preset():
  for kind, path in walkDir(
      OpSyncAggregateDir, relative = true, checkDir = true):
    runTest(OpSyncAggregateDir, path)