mirror of
https://github.com/status-im/nimbus-eth1.git
synced 2025-01-14 14:24:32 +00:00
0d4ef023ed
* Aristo: Code cosmetics, e.g. update some CamelCase names * CoreDb+Aristo: Provide oldest known state root implied details: The Aristo journal allows to recover earlier but not all state roots. * Aristo: Fix journal backward index operator, e.g. `[^1]` * Aristo: Fix journal updater why: The `fifosStore()` store function slightly misinterpreted the update instructions when translation is to database `put()` functions. The effect was that the journal was ever growing due to stale entries which were never deleted. * CoreDb+Aristo: Provide utils for purging stale data from the KVT details: See earlier patch, not all state roots are available. This patch provides a mapping from some state root to a block number and allows to remove all KVT data related to a particular block number * Aristo+Kvt: Implement a clean up schedule for expired data in KVT why: For a single state ledger like `Aristo`, there is only a limited backlog of states. So KVT data (i.e. headers etc.) are cleaned up regularly * Fix copyright year
114 lines
4.2 KiB
Nim
114 lines
4.2 KiB
Nim
# nimbus-eth1
|
|
# Copyright (c) 2023-2024 Status Research & Development GmbH
|
|
# Licensed under either of
|
|
# * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE) or
|
|
# http://www.apache.org/licenses/LICENSE-2.0)
|
|
# * MIT license ([LICENSE-MIT](LICENSE-MIT) or
|
|
# http://opensource.org/licenses/MIT)
|
|
# at your option. This file may not be copied, modified, or distributed
|
|
# except according to those terms.
|
|
|
|
## Aristo DB -- Consistency checks
|
|
## ===============================
|
|
##
|
|
{.push raises: [].}
|
|
|
|
import
|
|
std/[algorithm, sequtils, sets, tables],
|
|
eth/common,
|
|
stew/interval_set,
|
|
results,
|
|
./aristo_walk/persistent,
|
|
"."/[aristo_desc, aristo_get, aristo_init, aristo_utils],
|
|
./aristo_check/[check_be, check_journal, check_top]
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# Public functions
|
|
# ------------------------------------------------------------------------------
|
|
|
|
proc checkTop*(
|
|
db: AristoDbRef; # Database, top layer
|
|
proofMode = false; # Has proof nodes
|
|
): Result[void,(VertexID,AristoError)] =
|
|
## Verify that the cache structure is correct as it would be after `merge()`
|
|
## and `hashify()` operations. Unless `proofMode` is set `true` it would not
|
|
## fully check against the backend, which is typically not applicable after
|
|
## `delete()` operations.
|
|
##
|
|
## The following is verified:
|
|
##
|
|
## * Each `sTab[]` entry has a valid vertex which can be compiled as a node.
|
|
## If `proofMode` is set `false`, the Merkle hashes are recompiled and must
|
|
## match.
|
|
##
|
|
if proofMode:
|
|
? db.checkTopProofMode()
|
|
else:
|
|
? db.checkTopStrict()
|
|
|
|
db.checkTopCommon()
|
|
|
|
|
|
proc checkBE*(
|
|
db: AristoDbRef; # Database, top layer
|
|
relax = true; # Not re-compiling hashes if `true`
|
|
cache = true; # Also verify against top layer cache
|
|
fifos = false; # Also verify cascaded filter fifos
|
|
): Result[void,(VertexID,AristoError)] =
|
|
## Verify database backend structure. If the argument `relax` is set `false`,
|
|
## all necessary Merkle hashes are compiled and verified. If the argument
|
|
## `cache` is set `true`, the cache is also checked so that a safe operation
|
|
## (like `resolveBackendFilter()`) will leave the backend consistent.
|
|
##
|
|
## The following is verified:
|
|
##
|
|
## * Each vertex ID on the structural table can be represented as a Merkle
|
|
## patricia Tree node. If `relax` is set `false`, the Merkle hashes are
|
|
## all recompiled and must match.
|
|
##
|
|
## * The set of free vertex IDa as potentally suppliedby the ID generator
|
|
## state is disjunct to the set of already used vertex IDs on the database.
|
|
## Moreover, the union of both sets is equivalent to the set of positive
|
|
## `uint64` numbers.
|
|
##
|
|
case db.backend.kind:
|
|
of BackendMemory:
|
|
return MemBackendRef.checkBE(db, cache=cache, relax=relax)
|
|
of BackendRocksDB:
|
|
return RdbBackendRef.checkBE(db, cache=cache, relax=relax)
|
|
of BackendVoid:
|
|
return VoidBackendRef.checkBE(db, cache=cache, relax=relax)
|
|
|
|
proc checkJournal*(
|
|
db: AristoDbRef; # Database, top layer
|
|
): Result[void,(QueueID,AristoError)] =
|
|
## Verify database backend journal.
|
|
case db.backend.kind:
|
|
of BackendMemory:
|
|
return MemBackendRef.checkJournal(db)
|
|
of BackendRocksDB:
|
|
return RdbBackendRef.checkJournal(db)
|
|
of BackendVoid:
|
|
return ok() # no journal
|
|
|
|
|
|
proc check*(
|
|
db: AristoDbRef; # Database, top layer
|
|
relax = false; # Check existing hashes only
|
|
cache = true; # Also verify against top layer cache
|
|
fifos = true; # Also verify cascaded filter fifos
|
|
proofMode = false; # Has proof nodes
|
|
): Result[void,(VertexID,AristoError)] =
|
|
## Shortcut for running `checkTop()` followed by `checkBE()`
|
|
? db.checkTop(proofMode = proofMode)
|
|
? db.checkBE(relax = relax, cache = cache, fifos = fifos)
|
|
if fifos:
|
|
let rc = db.checkJournal()
|
|
if rc.isErr:
|
|
return err((VertexID(0),rc.error[1]))
|
|
ok()
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# End
|
|
# ------------------------------------------------------------------------------
|