mirror of
https://github.com/status-im/nimbus-eth1.git
synced 2025-02-08 18:23:59 +00:00
833719a866
These create only confusion as if they are actual different types and it is within their usage already clear what they are about because of the name of the variable or the function. They are also nowhere aliased like this in any of the Portal specification.
105 lines
3.5 KiB
Nim
105 lines
3.5 KiB
Nim
# Fluffy
|
|
# Copyright (c) 2023-2024 Status Research & Development GmbH
|
|
# Licensed and distributed under either of
|
|
# * MIT license (license terms in the root directory or at https://opensource.org/licenses/MIT).
|
|
# * Apache v2 license (license terms in the root directory or at https://www.apache.org/licenses/LICENSE-2.0).
|
|
# at your option. This file may not be copied, modified, or distributed except according to those terms.
|
|
|
|
# As per spec:
|
|
# https://github.com/ethereum/portal-network-specs/blob/master/state-network.md#content-keys-and-content-ids
|
|
|
|
{.push raises: [].}
|
|
|
|
import
|
|
nimcrypto/[hash, sha2, keccak],
|
|
results,
|
|
stint,
|
|
eth/common/hashes,
|
|
ssz_serialization,
|
|
./nibbles
|
|
|
|
export ssz_serialization, common_types, hash, results
|
|
|
|
type
|
|
ContentType* = enum
|
|
# Note: Need to add this unused value as a case object with an enum without
|
|
# a 0 valueis not allowed: "low(contentType) must be 0 for discriminant".
|
|
# For prefix values that are in the enum gap, the deserialization will fail
|
|
# at runtime as is wanted.
|
|
# In the future it might be possible that this will fail at compile time for
|
|
# the SSZ Union type, but currently it is allowed in the implementation, and
|
|
# the SSZ spec is not explicit about disallowing this.
|
|
unused = 0x00
|
|
accountTrieNode = 0x20
|
|
contractTrieNode = 0x21
|
|
contractCode = 0x22
|
|
|
|
AccountTrieNodeKey* = object
|
|
path*: Nibbles
|
|
nodeHash*: Hash32
|
|
|
|
ContractTrieNodeKey* = object
|
|
addressHash*: Hash32
|
|
path*: Nibbles
|
|
nodeHash*: Hash32
|
|
|
|
ContractCodeKey* = object
|
|
addressHash*: Hash32
|
|
codeHash*: Hash32
|
|
|
|
ContentKey* = object
|
|
case contentType*: ContentType
|
|
of unused:
|
|
discard
|
|
of accountTrieNode:
|
|
accountTrieNodeKey*: AccountTrieNodeKey
|
|
of contractTrieNode:
|
|
contractTrieNodeKey*: ContractTrieNodeKey
|
|
of contractCode:
|
|
contractCodeKey*: ContractCodeKey
|
|
|
|
ContentKeyType* = AccountTrieNodeKey | ContractTrieNodeKey | ContractCodeKey
|
|
|
|
func init*(T: type AccountTrieNodeKey, path: Nibbles, nodeHash: Hash32): T {.inline.} =
|
|
T(path: path, nodeHash: nodeHash)
|
|
|
|
func init*(
|
|
T: type ContractTrieNodeKey, addressHash: Hash32, path: Nibbles, nodeHash: Hash32
|
|
): T {.inline.} =
|
|
T(addressHash: addressHash, path: path, nodeHash: nodeHash)
|
|
|
|
func init*(
|
|
T: type ContractCodeKey, addressHash: Hash32, codeHash: Hash32
|
|
): T {.inline.} =
|
|
T(addressHash: addressHash, codeHash: codeHash)
|
|
|
|
func toContentKey*(key: AccountTrieNodeKey): ContentKey {.inline.} =
|
|
ContentKey(contentType: accountTrieNode, accountTrieNodeKey: key)
|
|
|
|
func toContentKey*(key: ContractTrieNodeKey): ContentKey {.inline.} =
|
|
ContentKey(contentType: contractTrieNode, contractTrieNodeKey: key)
|
|
|
|
func toContentKey*(key: ContractCodeKey): ContentKey {.inline.} =
|
|
ContentKey(contentType: contractCode, contractCodeKey: key)
|
|
|
|
proc readSszBytes*(data: openArray[byte], val: var ContentKey) {.raises: [SszError].} =
|
|
mixin readSszValue
|
|
if data.len() > 0 and data[0] == ord(unused):
|
|
raise newException(MalformedSszError, "SSZ selector is unused value")
|
|
|
|
readSszValue(data, val)
|
|
|
|
func encode*(contentKey: ContentKey): ContentKeyByteList {.inline.} =
|
|
doAssert(contentKey.contentType != unused)
|
|
ContentKeyByteList.init(SSZ.encode(contentKey))
|
|
|
|
func decode*(
|
|
T: type ContentKey, contentKey: ContentKeyByteList
|
|
): Result[T, string] {.inline.} =
|
|
decodeSsz(contentKey.asSeq(), T)
|
|
|
|
func toContentId*(contentKey: ContentKeyByteList): ContentId {.inline.} =
|
|
# TODO: Should we try to parse the content key here for invalid ones?
|
|
let idHash = sha256.digest(contentKey.asSeq())
|
|
readUintBE[256](idHash.data)
|