mirror of
https://github.com/status-im/nimbus-eth1.git
synced 2025-02-11 11:37:01 +00:00
cd1d370543
* Update docu * Update Aristo/Kvt constructor prototype why: Previous version used an `enum` value to indicate what backend is to be used. This was replaced by using the backend object type. * Rewrite `hikeUp()` return code into `Result[Hike,(Hike,AristoError)]` why: Better code maintenance. Previously, the `Hike` object was returned. It had an internal error field so partial success was also available on a failure. This error field has been removed. * Use `openArray[byte]` rather than `Blob` in functions prototypes * Provide synchronised multi instance transactions why: The `CoreDB` object was geared towards the legacy DB which used a single transaction for the key-value backend DB. Different state roots are provided by the backend database, so all instances work directly on the same backend. Aristo db instances have different in-memory mappings (aka different state roots) and the transactions are on top of there mappings. So each instance might run different transactions. Multi instance transactions are a compromise to converge towards the legacy behaviour. The synchronised transactions span over all instances available at the time when base transaction was opened. Instances created later are unaffected. * Provide key-value pair database iterator why: Needed in `CoreDB` for `replicate()` emulation also: Some update of internal code * Extend API (i.e. prototype variants) why: Needed for `CoreDB` geared towards the legacy backend which has a more basic API than Aristo.
96 lines
2.8 KiB
Nim
96 lines
2.8 KiB
Nim
# nimbus-eth1
|
|
# Copyright (c) 2021 Status Research & Development GmbH
|
|
# Licensed under either of
|
|
# * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE) or
|
|
# http://www.apache.org/licenses/LICENSE-2.0)
|
|
# * MIT license ([LICENSE-MIT](LICENSE-MIT) or
|
|
# http://opensource.org/licenses/MIT)
|
|
# at your option. This file may not be copied, modified, or distributed
|
|
# except according to those terms.
|
|
|
|
## Kvt DB -- Common functions
|
|
## ==========================
|
|
##
|
|
{.push raises: [].}
|
|
|
|
import
|
|
eth/common,
|
|
results,
|
|
./kvt_desc/desc_backend,
|
|
./kvt_desc
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# Private helpers
|
|
# ------------------------------------------------------------------------------
|
|
|
|
proc getBE*(
|
|
db: KvtDbRef; # Database
|
|
key: openArray[byte]; # Key of database record
|
|
): Result[Blob,KvtError] =
|
|
## For the argument `key` return the associated value from the backend
|
|
## database if available.
|
|
##
|
|
let be = db.backend
|
|
if not be.isNil:
|
|
return be.getKvpFn key
|
|
err(GetNotFound)
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# Public functions, converters
|
|
# ------------------------------------------------------------------------------
|
|
|
|
proc put*(
|
|
db: KvtDbRef; # Database
|
|
key: openArray[byte]; # Key of database record to store
|
|
data: openArray[byte]; # Value of database record to store
|
|
): Result[void,KvtError] =
|
|
## For the argument `key` associated the argument `data` as value (which
|
|
## will be marked in the top layer cache.)
|
|
if key.len == 0:
|
|
return err(KeyInvalid)
|
|
if data.len == 0:
|
|
return err(DataInvalid)
|
|
|
|
db.top.tab[@key] = @data
|
|
ok()
|
|
|
|
|
|
proc del*(
|
|
db: KvtDbRef; # Database
|
|
key: openArray[byte]; # Key of database record to delete
|
|
): Result[void,KvtError] =
|
|
## For the argument `key` delete the associated value (which will be marked
|
|
## in the top layer cache.)
|
|
if key.len == 0:
|
|
return err(KeyInvalid)
|
|
|
|
let rc = db.getBE(key)
|
|
if rc.isOk:
|
|
db.top.tab[@key] = EmptyBlob
|
|
elif rc.error == GetNotFound:
|
|
db.top.tab.del @key
|
|
else:
|
|
return err(rc.error)
|
|
|
|
ok()
|
|
|
|
# ------------
|
|
|
|
proc get*(
|
|
db: KvtDbRef; # Database
|
|
key: openArray[byte]; # Key of database record
|
|
): Result[Blob,KvtError] =
|
|
## For the argument `key` return the associated value preferably from the
|
|
## top layer, or the database otherwise.
|
|
##
|
|
if key.len == 0:
|
|
return err(KeyInvalid)
|
|
let data = db.top.tab.getOrVoid @key
|
|
if data.isValid:
|
|
return ok(data)
|
|
db.getBE key
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# End
|
|
# ------------------------------------------------------------------------------
|