mirror of
https://github.com/status-im/nimbus-eth1.git
synced 2025-01-09 03:52:08 +00:00
221e6c9e2f
* Nimbus folder environment update details: * Integrated `CoreDbRef` for the sources in the `nimbus` sub-folder. * The `nimbus` program does not compile yet as it needs the updates in the parallel `stateless` sub-folder. * Stateless environment update details: * Integrated `CoreDbRef` for the sources in the `stateless` sub-folder. * The `nimbus` program compiles now. * Premix environment update details: * Integrated `CoreDbRef` for the sources in the `premix` sub-folder. * Fluffy environment update details: * Integrated `CoreDbRef` for the sources in the `fluffy` sub-folder. * Tools environment update details: * Integrated `CoreDbRef` for the sources in the `tools` sub-folder. * Nodocker environment update details: * Integrated `CoreDbRef` for the sources in the `hive_integration/nodocker` sub-folder. * Tests environment update details: * Integrated `CoreDbRef` for the sources in the `tests` sub-folder. * The unit tests compile and run cleanly now. * Generalise `CoreDbRef` to any `select_backend` supported database why: Generalisation was just missed due to overcoming some compiler oddity which was tied to rocksdb for testing. * Suppress compiler warning for `newChainDB()` why: Warning was added to this function which must be wrapped so that any `CatchableError` is re-raised as `Defect`. * Split off persistent `CoreDbRef` constructor into separate file why: This allows to compile a memory only database version without linking the backend library. * Use memory `CoreDbRef` database by default detail: Persistent DB constructor needs to import `db/core_db/persistent why: Most tests use memory DB anyway. This avoids linking `-lrocksdb` or any other backend by default. * fix `toLegacyBackend()` availability check why: got garbled after memory/persistent split. * Clarify raw access to MPT for snap sync handler why: Logically, `kvt` is not the raw access for the hexary trie (although this holds for the legacy database)
131 lines
4.2 KiB
Nim
131 lines
4.2 KiB
Nim
# Nimbus
|
|
# Copyright (c) 2021 Status Research & Development GmbH
|
|
# Licensed under either of
|
|
# * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE) or
|
|
# http://www.apache.org/licenses/LICENSE-2.0)
|
|
# * MIT license ([LICENSE-MIT](LICENSE-MIT) or
|
|
# http://opensource.org/licenses/MIT)
|
|
# at your option. This file may not be copied, modified, or distributed
|
|
# except according to those terms.
|
|
|
|
## Worker peers scheduler template
|
|
## ===============================
|
|
##
|
|
## Public descriptors
|
|
|
|
{.push raises: [].}
|
|
|
|
import
|
|
eth/p2p,
|
|
../core/chain,
|
|
./handlers/eth
|
|
|
|
export
|
|
chain
|
|
|
|
type
|
|
BuddyRunState* = enum
|
|
Running = 0 ## Running, default state
|
|
Stopped ## Stopped or about stopping
|
|
ZombieStop ## Abandon/ignore (wait for pushed out of LRU table)
|
|
ZombieRun ## Extra zombie state to potentially recover from
|
|
|
|
BuddyCtrlRef* = ref object
|
|
## Control and state settings
|
|
runState: BuddyRunState ## Access with getters
|
|
multiOk*: bool ## Triggers `runSingle()` mode unless `true`
|
|
|
|
BuddyRef*[S,W] = ref object
|
|
## Worker peer state descriptor.
|
|
ctx*: CtxRef[S] ## Shared data descriptor back reference
|
|
peer*: Peer ## Reference to eth p2pProtocol entry
|
|
ctrl*: BuddyCtrlRef ## Control and state settings
|
|
only*: W ## Worker peer specific data
|
|
|
|
CtxRef*[S] = ref object
|
|
## Shared state among all syncing peer workers (aka buddies.)
|
|
buddiesMax*: int ## Max number of buddies
|
|
ethWireCtx*: EthWireRef ## Eth protocol wire context (if available)
|
|
chain*: ChainRef ## Block chain database (no need for `Peer`)
|
|
poolMode*: bool ## Activate `runPool()` workers if set `true`
|
|
daemon*: bool ## Enable global background job
|
|
exCtrlFile*: Option[string] ## Extra instructions file (if any)
|
|
pool*: S ## Shared context for all worker peers
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# Public functions
|
|
# ------------------------------------------------------------------------------
|
|
|
|
proc `$`*[S,W](worker: BuddyRef[S,W]): string =
|
|
$worker.peer & "$" & $worker.ctrl.runState
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# Public getters, `BuddyRunState` execution control functions
|
|
# ------------------------------------------------------------------------------
|
|
|
|
proc state*(ctrl: BuddyCtrlRef): BuddyRunState =
|
|
## Getter (logging only, details of `BuddyCtrl` are private)
|
|
ctrl.runState
|
|
|
|
proc running*(ctrl: BuddyCtrlRef): bool =
|
|
## Getter, if `true` if `ctrl.state()` is `Running`
|
|
ctrl.runState == Running
|
|
|
|
proc stopped*(ctrl: BuddyCtrlRef): bool =
|
|
## Getter, if `true`, if `ctrl.state()` is not `Running`
|
|
ctrl.runState != Running
|
|
|
|
proc zombie*(ctrl: BuddyCtrlRef): bool =
|
|
## Getter, `true` if `ctrl.state()` is `Zombie` (i.e. not `running()` and
|
|
## not `stopped()`)
|
|
ctrl.runState in {ZombieStop, ZombieRun}
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# Public setters, `BuddyRunState` execution control functions
|
|
# ------------------------------------------------------------------------------
|
|
|
|
proc `zombie=`*(ctrl: BuddyCtrlRef; value: bool) =
|
|
## Setter
|
|
if value:
|
|
case ctrl.runState:
|
|
of Running:
|
|
ctrl.runState = ZombieRun
|
|
of Stopped:
|
|
ctrl.runState = ZombieStop
|
|
else:
|
|
discard
|
|
else:
|
|
case ctrl.runState:
|
|
of ZombieRun:
|
|
ctrl.runState = Running
|
|
of ZombieStop:
|
|
ctrl.runState = Stopped
|
|
else:
|
|
discard
|
|
|
|
proc `stopped=`*(ctrl: BuddyCtrlRef; value: bool) =
|
|
## Setter
|
|
if value:
|
|
case ctrl.runState:
|
|
of Running:
|
|
ctrl.runState = Stopped
|
|
else:
|
|
discard
|
|
else:
|
|
case ctrl.runState:
|
|
of Stopped:
|
|
ctrl.runState = Running
|
|
else:
|
|
discard
|
|
|
|
proc `forceRun=`*(ctrl: BuddyCtrlRef; value: bool) =
|
|
## Setter, gets out of `Zombie` jail/locked state with `true argument.
|
|
if value:
|
|
ctrl.runState = Running
|
|
else:
|
|
ctrl.stopped = true
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# End
|
|
# ------------------------------------------------------------------------------
|