mirror of
https://github.com/status-im/nimbus-eth1.git
synced 2025-01-15 06:44:12 +00:00
143f2e99f5
* Aristo: Rename journal related sources and functions why: Previously, the naming was hinged on the phrases `fifo`, `filter` etc. which reflect the inner workings of cascaded filters. This was unfortunate for reading/understanding the source code for actions where the focus is the journal as a whole. * Aristo: Fix buffer overflow (path length truncating error) * Aristo: Tighten `hikeUp()` stop check, update error code why: Detect dangling vertex links. These are legit with `snap` sync processing but not with regular processing. * Aristo: Raise assert in regular mode `merge()` at a dangling link/edge why: With `snap` sync processing, partial trees are ok and can be amended. Not so in regular mode. Previously there was only a debug message when a non-legit dangling edge was encountered. * Aristo: Make sure that vertices are copied before modification why: Otherwise vertices from lower layers might also be modified * Aristo: Fix relaxed mode for validity checker `check()` * Remove cruft * Aristo: Update API for transaction handling details: + Split `aristo_tx.nim` into sub-modules + Split `forkWith()` into `findTx()` + `forkTx()` + Removed `forkTop()`, `forkBase()` (now superseded by new `forkTx()`) * CoreDb+Aristo: Fix initialiser (missing methods)
92 lines
2.9 KiB
Nim
92 lines
2.9 KiB
Nim
# nimbus-eth1
|
|
# Copyright (c) 2023-2024 Status Research & Development GmbH
|
|
# Licensed under either of
|
|
# * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE) or
|
|
# http://www.apache.org/licenses/LICENSE-2.0)
|
|
# * MIT license ([LICENSE-MIT](LICENSE-MIT) or
|
|
# http://opensource.org/licenses/MIT)
|
|
# at your option. This file may not be copied, modified, or distributed
|
|
# except according to those terms.
|
|
|
|
## Aristo DB -- Transaction stow/save helper
|
|
## =========================================
|
|
##
|
|
{.push raises: [].}
|
|
|
|
import
|
|
std/options,
|
|
results,
|
|
".."/[aristo_desc, aristo_get, aristo_journal, aristo_layers, aristo_hashify]
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# Public functions
|
|
# ------------------------------------------------------------------------------
|
|
|
|
proc txStow*(
|
|
db: AristoDbRef; # Database
|
|
nxtFid: Option[FilterID]; # Next filter ID (zero is OK)
|
|
persistent: bool; # Stage only unless `true`
|
|
chunkedMpt: bool; # Partial data (e.g. from `snap`)
|
|
): Result[void,AristoError] =
|
|
## Worker for `stow()` and `persist()` variants.
|
|
##
|
|
if not db.txRef.isNil:
|
|
return err(TxPendingTx)
|
|
if 0 < db.stack.len:
|
|
return err(TxStackGarbled)
|
|
if persistent and not db.journalUpdateOk():
|
|
return err(TxBackendNotWritable)
|
|
|
|
# Update Merkle hashes (unless disabled)
|
|
db.hashify().isOkOr:
|
|
return err(error[1])
|
|
|
|
let fwd = db.journalFwdFilter(db.top, chunkedMpt).valueOr:
|
|
return err(error[1])
|
|
|
|
if fwd.isValid:
|
|
# Merge `top` layer into `roFilter`
|
|
db.journalMerge(fwd).isOkOr:
|
|
return err(error[1])
|
|
|
|
# Special treatment for `snap` proofs (aka `chunkedMpt`)
|
|
let final =
|
|
if chunkedMpt: LayerFinalRef(fRpp: db.top.final.fRpp)
|
|
else: LayerFinalRef()
|
|
|
|
# New empty top layer (probably with `snap` proofs and `vGen` carry over)
|
|
db.top = LayerRef(
|
|
delta: LayerDeltaRef(),
|
|
final: final)
|
|
if db.roFilter.isValid:
|
|
db.top.final.vGen = db.roFilter.vGen
|
|
else:
|
|
let rc = db.getIdgUbe()
|
|
if rc.isOk:
|
|
db.top.final.vGen = rc.value
|
|
else:
|
|
# It is OK if there was no `Idg`. Otherwise something serious happened
|
|
# and there is no way to recover easily.
|
|
doAssert rc.error == GetIdgNotFound
|
|
|
|
if persistent:
|
|
# Merge `roFiler` into persistent tables
|
|
? db.journalUpdate nxtFid
|
|
db.roFilter = FilterRef(nil)
|
|
|
|
# Special treatment for `snap` proofs (aka `chunkedMpt`)
|
|
let final =
|
|
if chunkedMpt: LayerFinalRef(vGen: db.vGen, fRpp: db.top.final.fRpp)
|
|
else: LayerFinalRef(vGen: db.vGen)
|
|
|
|
# New empty top layer (probably with `snap` proofs carry over)
|
|
db.top = LayerRef(
|
|
delta: LayerDeltaRef(),
|
|
final: final,
|
|
txUid: db.top.txUid)
|
|
ok()
|
|
|
|
# ------------------------------------------------------------------------------
|
|
# End
|
|
# ------------------------------------------------------------------------------
|