mirror of
https://github.com/status-im/nim-rocksdb.git
synced 2025-02-20 10:58:32 +00:00
5f6282e8d4
* Column families support (#34) * Update library to support column families. If not specified, uses the 'default' column family. * Added tests for column family changes. * Update library version and readme. * Updated the librocksdb c library to the latest stable version. * Started rewrite of library. * Commit library rewrite progress. * Completed initial rewrite and refactored tests. * Completed implementation of backup engine. * Added tests for new types. * Completed tests for existing features. * Remove features not supported by older versions of RocksDB to fix CI (temporary fix). * Remove flush before backup support from BackupEngine to fix CI. * Transactions support (#36) * Update library to support column families. If not specified, uses the 'default' column family. * Added tests for column family changes. * Update library version and readme. * Updated the librocksdb c library to the latest stable version. * Started rewrite of library. * Commit library rewrite progress. * Completed initial rewrite and refactored tests. * Completed implementation of backup engine. * Added tests for new types. * Completed tests for existing features. * Remove features not supported by older versions of RocksDB to fix CI (temporary fix). * Remove flush before backup support from BackupEngine to fix CI. * Implemented RocksDB iterator. * Implemented pairs iterator. * Completed implementation of WriteBatch with tests. * Fix example code. * Completed implementation of TransactionDb. * Support setting default column family. * Remove unneeded usage of var for ref type parameters. * Completed transactiondb tests. * Improve and refactor rocksdb test. * Added support for ingesting sst files using the SstFileWriter. (#37) * Create ColFamilyReadOnly and ColFamilyReadWrite types for using a specific column family. * Use inline pragma for small procs and add lock to RocksDbRef type close to prevent double free. * Added documentation for the public API. * Initial implementation of sst filewriter. * Added tests for sstfilewriter. * Documentation minor improvements.
102 lines
2.8 KiB
Nim
102 lines
2.8 KiB
Nim
# Nim-RocksDB
|
|
# Copyright 2024 Status Research & Development GmbH
|
|
# Licensed under either of
|
|
#
|
|
# * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE) or http://www.apache.org/licenses/LICENSE-2.0)
|
|
# * GPL license, version 2.0, ([LICENSE-GPLv2](LICENSE-GPLv2) or https://www.gnu.org/licenses/old-licenses/gpl-2.0.en.html)
|
|
#
|
|
# at your option. This file may not be copied, modified, or distributed except according to those terms.
|
|
|
|
## A `SstFileWriterRef` is used to create sst files that can be added to the database later.
|
|
|
|
{.push raises: [].}
|
|
|
|
import
|
|
./lib/librocksdb,
|
|
./internal/utils,
|
|
./options/dbopts,
|
|
./rocksresult
|
|
|
|
export
|
|
rocksresult
|
|
|
|
type
|
|
SstFileWriterPtr* = ptr rocksdb_sstfilewriter_t
|
|
EnvOptionsPtr = ptr rocksdb_envoptions_t
|
|
|
|
SstFileWriterRef* = ref object
|
|
cPtr: SstFileWriterPtr
|
|
envOptsPtr: EnvOptionsPtr
|
|
dbOpts: DbOptionsRef
|
|
|
|
proc openSstFileWriter*(
|
|
filePath: string,
|
|
dbOpts = defaultDbOptions()): RocksDBResult[SstFileWriterRef] =
|
|
## Creates a new `SstFileWriterRef` and opens the file at the given `filePath`.
|
|
doAssert not dbOpts.isClosed()
|
|
|
|
let envOptsPtr = rocksdb_envoptions_create()
|
|
let writer = SstFileWriterRef(
|
|
cPtr: rocksdb_sstfilewriter_create(envOptsPtr, dbOpts.cPtr),
|
|
envOptsPtr: envOptsPtr,
|
|
dbOpts: dbOpts)
|
|
|
|
var errors: cstring
|
|
rocksdb_sstfilewriter_open(
|
|
writer.cPtr,
|
|
filePath.cstring,
|
|
cast[cstringArray](errors.addr))
|
|
bailOnErrors(errors)
|
|
|
|
ok(writer)
|
|
|
|
proc isClosed*(writer: SstFileWriterRef): bool {.inline.} =
|
|
## Returns `true` if the `SstFileWriterRef` is closed and `false` otherwise.
|
|
writer.cPtr.isNil()
|
|
|
|
proc put*(
|
|
writer: SstFileWriterRef,
|
|
key: openArray[byte],
|
|
val: openArray[byte]): RocksDBResult[void] =
|
|
## Add a key-value pair to the sst file.
|
|
|
|
var errors: cstring
|
|
rocksdb_sstfilewriter_put(
|
|
writer.cPtr,
|
|
cast[cstring](unsafeAddr key[0]), csize_t(key.len),
|
|
cast[cstring](unsafeAddr val[0]), csize_t(val.len),
|
|
cast[cstringArray](errors.addr))
|
|
bailOnErrors(errors)
|
|
|
|
ok()
|
|
|
|
proc delete*(writer: SstFileWriterRef, key: openArray[byte]): RocksDBResult[void] =
|
|
## Delete a key-value pair from the sst file.
|
|
|
|
var errors: cstring
|
|
rocksdb_sstfilewriter_delete(
|
|
writer.cPtr,
|
|
cast[cstring](unsafeAddr key[0]), csize_t(key.len),
|
|
cast[cstringArray](errors.addr))
|
|
bailOnErrors(errors)
|
|
|
|
ok()
|
|
|
|
proc finish*(writer: SstFileWriterRef): RocksDBResult[void] =
|
|
## Finish the process and close the sst file.
|
|
doAssert not writer.isClosed()
|
|
|
|
var errors: cstring
|
|
rocksdb_sstfilewriter_finish(writer.cPtr, cast[cstringArray](errors.addr))
|
|
bailOnErrors(errors)
|
|
|
|
ok()
|
|
|
|
proc close*(writer: SstFileWriterRef) =
|
|
## Closes the `SstFileWriterRef`.
|
|
if not writer.isClosed():
|
|
rocksdb_envoptions_destroy(writer.envOptsPtr)
|
|
writer.envOptsPtr = nil
|
|
rocksdb_sstfilewriter_destroy(writer.cPtr)
|
|
writer.cPtr = nil
|