import
  eth_common/[eth_types, state_accessors]

# TODO: Perhaps we can move this to eth-common

proc getBlockHeaders*(db: AbstractChainDb,
                      req: BlocksRequest): seq[BlockHeader] =
  result = newSeqOfCap[BlockHeader](req.maxResults)

  var foundBlock: BlockHeader
  if db.getBlockHeader(req.startBlock, foundBlock):
    result.add foundBlock

    while uint64(result.len) < req.maxResults:
      if not db.getSuccessorHeader(foundBlock, foundBlock):
        break
      result.add foundBlock

template fetcher*(fetcherName, fetchingFunc, InputType, ResultType: untyped) =
  proc fetcherName*(db: AbstractChainDb,
                    lookups: openarray[InputType]): seq[ResultType] =
    for lookup in lookups:
      let fetched = fetchingFunc(db, lookup)
      if fetched.hasData:
        # TODO: should there be an else clause here.
        # Is the peer responsible of figuring out that
        # some of the requested items were not found?
        result.add deref(fetched)

fetcher getContractCodes,  getContractCode,  ContractCodeRequest, Blob
fetcher getBlockBodies,    getBlockBody,     KeccakHash,    BlockBody
fetcher getStorageNodes,   getStorageNode,   KeccakHash,    Blob
fetcher getReceipts,       getReceipt,       KeccakHash,    Receipt
fetcher getProofs,         getProof,         ProofRequest,  Blob
fetcher getHeaderProofs,   getHeaderProof,   ProofRequest,  Blob

proc getHelperTrieProofs*(db: AbstractChainDb,
                          reqs: openarray[HelperTrieProofRequest],
                          outNodes: var seq[Blob], outAuxData: var seq[Blob]) =
  discard