mirror of
https://github.com/status-im/nim-dagger.git
synced 2025-01-19 03:02:57 +00:00
de88fd2c53
* implement a logging proxy The logging proxy: - prevents the need to import chronicles (as well as export except toJson), - prevents the need to override `writeValue` or use or import nim-json-seralization elsewhere in the codebase, allowing for sole use of utils/json for de/serialization, - and handles json formatting correctly in chronicles json sinks * Rename logging -> logutils to avoid ambiguity with common names * clean up * add setProperty for JsonRecord, remove nim-json-serialization conflict * Allow specifying textlines and json format separately Not specifying a LogFormat will apply the formatting to both textlines and json sinks. Specifying a LogFormat will apply the formatting to only that sink. * remove unneeded usages of std/json We only need to import utils/json instead of std/json * move serialization from rest/json to utils/json so it can be shared * fix NoColors ambiguity Was causing unit tests to fail on Windows. * Remove nre usage to fix Windows error Windows was erroring with `could not load: pcre64.dll`. Instead of fixing that error, remove the pcre usage :) * Add logutils module doc * Shorten logutils.formatIt for `NBytes` Both json and textlines formatIt were not needed, and could be combined into one formatIt * remove debug integration test config debug output and logformat of json for integration test logs * Use ## module doc to support docgen * bump nim-poseidon2 to export fromBytes Before the changes in this branch, fromBytes was likely being resolved by nim-stew, or other dependency. With the changes in this branch, that dependency was removed and fromBytes could no longer be resolved. By exporting fromBytes from nim-poseidon, the correct resolution is now happening. * fixes to get compiling after rebasing master * Add support for Result types being logged using formatIt
75 lines
2.1 KiB
Nim
75 lines
2.1 KiB
Nim
import pkg/questionable
|
|
import pkg/questionable/results
|
|
|
|
import ../../blocktype as bt
|
|
import ../../logutils
|
|
import ../../market
|
|
import ../salesagent
|
|
import ../statemachine
|
|
import ./errorhandling
|
|
import ./cancelled
|
|
import ./failed
|
|
import ./filled
|
|
import ./initialproving
|
|
import ./errored
|
|
|
|
type
|
|
SaleDownloading* = ref object of ErrorHandlingState
|
|
|
|
logScope:
|
|
topics = "marketplace sales downloading"
|
|
|
|
method `$`*(state: SaleDownloading): string = "SaleDownloading"
|
|
|
|
method onCancelled*(state: SaleDownloading, request: StorageRequest): ?State =
|
|
return some State(SaleCancelled())
|
|
|
|
method onFailed*(state: SaleDownloading, request: StorageRequest): ?State =
|
|
return some State(SaleFailed())
|
|
|
|
method onSlotFilled*(state: SaleDownloading, requestId: RequestId,
|
|
slotIndex: UInt256): ?State =
|
|
return some State(SaleFilled())
|
|
|
|
method run*(state: SaleDownloading, machine: Machine): Future[?State] {.async.} =
|
|
let agent = SalesAgent(machine)
|
|
let data = agent.data
|
|
let context = agent.context
|
|
let reservations = context.reservations
|
|
|
|
without onStore =? context.onStore:
|
|
raiseAssert "onStore callback not set"
|
|
|
|
without request =? data.request:
|
|
raiseAssert "no sale request"
|
|
|
|
without reservation =? data.reservation:
|
|
raiseAssert("no reservation")
|
|
|
|
logScope:
|
|
requestId = request.id
|
|
slotIndex = data.slotIndex
|
|
reservationId = reservation.id
|
|
availabilityId = reservation.availabilityId
|
|
|
|
proc onBlocks(blocks: seq[bt.Block]): Future[?!void] {.async.} =
|
|
# release batches of blocks as they are written to disk and
|
|
# update availability size
|
|
var bytes: uint = 0
|
|
for blk in blocks:
|
|
bytes += blk.data.len.uint
|
|
|
|
trace "Releasing batch of bytes written to disk", bytes
|
|
return await reservations.release(reservation.id,
|
|
reservation.availabilityId,
|
|
bytes)
|
|
|
|
trace "Starting download"
|
|
if err =? (await onStore(request,
|
|
data.slotIndex,
|
|
onBlocks)).errorOption:
|
|
return some State(SaleErrored(error: err))
|
|
|
|
trace "Download complete"
|
|
return some State(SaleInitialProving())
|