mirror of
https://github.com/status-im/nim-dagger.git
synced 2025-03-03 15:50:57 +00:00
962fc1cd95
* openAPI: StorageRequestCreation: reward => pricePerByte, collateral => collateralPerByte * purchasing: reward => pricePerByte, collateral => collateralPerByte * Updates availabilities and reservations to use totalCollateral, minPricePerByte, and maxCollateralPerByte * Uses correct div operator when operating on UInt256 * proposal updating totalCollateral in availability * makes sure that reading currentCollateral happens before freeing slot * Updates naming * fixes tests: unit and contracts * uses feat/price-per-byte branch for codex-contracts-eth * temporarily disables integration tests on CI * introduces high level <<totalCollateral>> property for a cleaner external interface * updates integration tests * Applies review comments * Updates description of totalCollateral in SalesAvailability * updates codex-contracts-eth (price-per-byte)
99 lines
3.2 KiB
Nim
99 lines
3.2 KiB
Nim
import pkg/questionable
|
|
import pkg/questionable/results
|
|
import pkg/metrics
|
|
|
|
import ../../logutils
|
|
import ../../market
|
|
import ../salesagent
|
|
import ../statemachine
|
|
import ./errorhandling
|
|
import ./cancelled
|
|
import ./failed
|
|
import ./filled
|
|
import ./ignored
|
|
import ./slotreserving
|
|
import ./errored
|
|
|
|
declareCounter(
|
|
codex_reservations_availability_mismatch, "codex reservations availability_mismatch"
|
|
)
|
|
|
|
type SalePreparing* = ref object of ErrorHandlingState
|
|
|
|
logScope:
|
|
topics = "marketplace sales preparing"
|
|
|
|
method `$`*(state: SalePreparing): string =
|
|
"SalePreparing"
|
|
|
|
method onCancelled*(state: SalePreparing, request: StorageRequest): ?State =
|
|
return some State(SaleCancelled())
|
|
|
|
method onFailed*(state: SalePreparing, request: StorageRequest): ?State =
|
|
return some State(SaleFailed())
|
|
|
|
method onSlotFilled*(
|
|
state: SalePreparing, requestId: RequestId, slotIndex: UInt256
|
|
): ?State =
|
|
return some State(SaleFilled())
|
|
|
|
method run*(state: SalePreparing, machine: Machine): Future[?State] {.async.} =
|
|
let agent = SalesAgent(machine)
|
|
let data = agent.data
|
|
let context = agent.context
|
|
let market = context.market
|
|
let reservations = context.reservations
|
|
|
|
await agent.retrieveRequest()
|
|
await agent.subscribe()
|
|
|
|
without request =? data.request:
|
|
raiseAssert "no sale request"
|
|
|
|
let slotId = slotId(data.requestId, data.slotIndex)
|
|
let state = await market.slotState(slotId)
|
|
if state != SlotState.Free and state != SlotState.Repair:
|
|
return some State(SaleIgnored(reprocessSlot: false, returnBytes: false))
|
|
|
|
# TODO: Once implemented, check to ensure the host is allowed to fill the slot,
|
|
# due to the [sliding window mechanism](https://github.com/codex-storage/codex-research/blob/master/design/marketplace.md#dispersal)
|
|
|
|
logScope:
|
|
slotIndex = data.slotIndex
|
|
slotSize = request.ask.slotSize
|
|
duration = request.ask.duration
|
|
pricePerBytePerSecond = request.ask.pricePerBytePerSecond
|
|
collateralPerByte = request.ask.collateralPerByte
|
|
|
|
without availability =?
|
|
await reservations.findAvailability(
|
|
request.ask.slotSize, request.ask.duration, request.ask.pricePerBytePerSecond,
|
|
request.ask.collateralPerByte,
|
|
):
|
|
debug "No availability found for request, ignoring"
|
|
|
|
return some State(SaleIgnored(reprocessSlot: true))
|
|
|
|
info "Availability found for request, creating reservation"
|
|
|
|
without reservation =?
|
|
await reservations.createReservation(
|
|
availability.id, request.ask.slotSize, request.id, data.slotIndex,
|
|
request.ask.collateralPerByte,
|
|
), error:
|
|
trace "Creation of reservation failed"
|
|
# Race condition:
|
|
# reservations.findAvailability (line 64) is no guarantee. You can never know for certain that the reservation can be created until after you have it.
|
|
# Should createReservation fail because there's no space, we proceed to SaleIgnored.
|
|
if error of BytesOutOfBoundsError:
|
|
# Lets monitor how often this happen and if it is often we can make it more inteligent to handle it
|
|
codex_reservations_availability_mismatch.inc()
|
|
return some State(SaleIgnored(reprocessSlot: true))
|
|
|
|
return some State(SaleErrored(error: error))
|
|
|
|
trace "Reservation created succesfully"
|
|
|
|
data.reservation = some reservation
|
|
return some State(SaleSlotReserving())
|