mirror of
https://github.com/status-im/nim-codex.git
synced 2025-01-11 03:16:16 +00:00
de88fd2c53
* implement a logging proxy The logging proxy: - prevents the need to import chronicles (as well as export except toJson), - prevents the need to override `writeValue` or use or import nim-json-seralization elsewhere in the codebase, allowing for sole use of utils/json for de/serialization, - and handles json formatting correctly in chronicles json sinks * Rename logging -> logutils to avoid ambiguity with common names * clean up * add setProperty for JsonRecord, remove nim-json-serialization conflict * Allow specifying textlines and json format separately Not specifying a LogFormat will apply the formatting to both textlines and json sinks. Specifying a LogFormat will apply the formatting to only that sink. * remove unneeded usages of std/json We only need to import utils/json instead of std/json * move serialization from rest/json to utils/json so it can be shared * fix NoColors ambiguity Was causing unit tests to fail on Windows. * Remove nre usage to fix Windows error Windows was erroring with `could not load: pcre64.dll`. Instead of fixing that error, remove the pcre usage :) * Add logutils module doc * Shorten logutils.formatIt for `NBytes` Both json and textlines formatIt were not needed, and could be combined into one formatIt * remove debug integration test config debug output and logformat of json for integration test logs * Use ## module doc to support docgen * bump nim-poseidon2 to export fromBytes Before the changes in this branch, fromBytes was likely being resolved by nim-stew, or other dependency. With the changes in this branch, that dependency was removed and fromBytes could no longer be resolved. By exporting fromBytes from nim-poseidon, the correct resolution is now happening. * fixes to get compiling after rebasing master * Add support for Result types being logged using formatIt
85 lines
2.5 KiB
Nim
85 lines
2.5 KiB
Nim
import pkg/questionable
|
|
import pkg/questionable/results
|
|
|
|
import ../../logutils
|
|
import ../../market
|
|
import ../salesagent
|
|
import ../statemachine
|
|
import ./errorhandling
|
|
import ./cancelled
|
|
import ./failed
|
|
import ./filled
|
|
import ./ignored
|
|
import ./downloading
|
|
import ./errored
|
|
|
|
type
|
|
SalePreparing* = ref object of ErrorHandlingState
|
|
|
|
logScope:
|
|
topics = "marketplace sales preparing"
|
|
|
|
method `$`*(state: SalePreparing): string = "SalePreparing"
|
|
|
|
method onCancelled*(state: SalePreparing, request: StorageRequest): ?State =
|
|
return some State(SaleCancelled())
|
|
|
|
method onFailed*(state: SalePreparing, request: StorageRequest): ?State =
|
|
return some State(SaleFailed())
|
|
|
|
method onSlotFilled*(state: SalePreparing, requestId: RequestId,
|
|
slotIndex: UInt256): ?State =
|
|
return some State(SaleFilled())
|
|
|
|
method run*(state: SalePreparing, machine: Machine): Future[?State] {.async.} =
|
|
let agent = SalesAgent(machine)
|
|
let data = agent.data
|
|
let context = agent.context
|
|
let market = context.market
|
|
let reservations = context.reservations
|
|
|
|
await agent.retrieveRequest()
|
|
await agent.subscribe()
|
|
|
|
without request =? data.request:
|
|
raiseAssert "no sale request"
|
|
|
|
let slotId = slotId(data.requestId, data.slotIndex)
|
|
let state = await market.slotState(slotId)
|
|
if state != SlotState.Free:
|
|
return some State(SaleIgnored())
|
|
|
|
# TODO: Once implemented, check to ensure the host is allowed to fill the slot,
|
|
# due to the [sliding window mechanism](https://github.com/codex-storage/codex-research/blob/master/design/marketplace.md#dispersal)
|
|
|
|
logScope:
|
|
slotIndex = data.slotIndex
|
|
slotSize = request.ask.slotSize
|
|
duration = request.ask.duration
|
|
pricePerSlot = request.ask.pricePerSlot
|
|
|
|
# availability was checked for this slot when it entered the queue, however
|
|
# check to the ensure that there is still availability as they may have
|
|
# changed since being added (other slots may have been processed in that time)
|
|
without availability =? await reservations.findAvailability(
|
|
request.ask.slotSize,
|
|
request.ask.duration,
|
|
request.ask.pricePerSlot,
|
|
request.ask.collateral):
|
|
debug "no availability found for request, ignoring"
|
|
|
|
return some State(SaleIgnored())
|
|
|
|
info "availability found for request, creating reservation"
|
|
|
|
without reservation =? await reservations.createReservation(
|
|
availability.id,
|
|
request.ask.slotSize,
|
|
request.id,
|
|
data.slotIndex
|
|
), error:
|
|
return some State(SaleErrored(error: error))
|
|
|
|
data.reservation = some reservation
|
|
return some State(SaleDownloading())
|