mirror of
https://github.com/status-im/nim-codex.git
synced 2025-01-11 03:16:16 +00:00
b3e57a37e2
* wire prover into node * stricter case object checks * return correct proof * misc renames * adding usefull traces * fix nodes and tolerance to match expected params * format challenges in logs * add circom compat to solidity groth16 convertion * update * bump time to give nodes time to load with all circom artifacts * misc * misc * use correct dataset geometry in erasure * make errors more searchable * use parens around `=? (await...)` calls * styling * styling * use push raises * fix to match constructor arguments * merge master * merge master * integration: fix proof parameters for a test Increased times due to ZK proof generation. Increased storage requirement because we're now hosting 5 slots instead of 1. * sales: calculate initial proof at start of period reason: this ensures that the period (and therefore the challenge) doesn't change while we're calculating the proof * integration: fix proof parameters for tests Increased times due to waiting on next period. Fixed data to be of right size. Updated expected payout due to hosting 5 slots. * sales: wait for stable proof challenge When the block pointer is nearing the wrap-around point, we wait another period before calculating a proof. * fix merge conflict --------- Co-authored-by: Dmitriy Ryajov <dryajov@gmail.com> Co-authored-by: Eric <5089238+emizzle@users.noreply.github.com>
64 lines
2.2 KiB
Nim
64 lines
2.2 KiB
Nim
import pkg/questionable/results
|
|
import ../../clock
|
|
import ../../logutils
|
|
import ../statemachine
|
|
import ../salesagent
|
|
import ./errorhandling
|
|
import ./filling
|
|
import ./cancelled
|
|
import ./errored
|
|
import ./failed
|
|
|
|
logScope:
|
|
topics = "marketplace sales initial-proving"
|
|
|
|
type
|
|
SaleInitialProving* = ref object of ErrorHandlingState
|
|
|
|
method `$`*(state: SaleInitialProving): string = "SaleInitialProving"
|
|
|
|
method onCancelled*(state: SaleInitialProving, request: StorageRequest): ?State =
|
|
return some State(SaleCancelled())
|
|
|
|
method onFailed*(state: SaleInitialProving, request: StorageRequest): ?State =
|
|
return some State(SaleFailed())
|
|
|
|
proc waitUntilNextPeriod(clock: Clock, periodicity: Periodicity) {.async.} =
|
|
trace "Waiting until next period"
|
|
let period = periodicity.periodOf(clock.now().u256)
|
|
let periodEnd = periodicity.periodEnd(period).truncate(int64)
|
|
await clock.waitUntil(periodEnd + 1)
|
|
|
|
proc waitForStableChallenge(market: Market, clock: Clock, slotId: SlotId) {.async.} =
|
|
let periodicity = await market.periodicity()
|
|
let downtime = await market.proofDowntime()
|
|
await clock.waitUntilNextPeriod(periodicity)
|
|
while (await market.getPointer(slotId)) > (256 - downtime):
|
|
await clock.waitUntilNextPeriod(periodicity)
|
|
|
|
method run*(state: SaleInitialProving, machine: Machine): Future[?State] {.async.} =
|
|
let data = SalesAgent(machine).data
|
|
let context = SalesAgent(machine).context
|
|
let market = context.market
|
|
let clock = context.clock
|
|
|
|
without request =? data.request:
|
|
raiseAssert "no sale request"
|
|
|
|
without onProve =? context.onProve:
|
|
raiseAssert "onProve callback not set"
|
|
|
|
debug "Waiting for a proof challenge that is valid for the entire period"
|
|
let slot = Slot(request: request, slotIndex: data.slotIndex)
|
|
await waitForStableChallenge(market, clock, slot.id)
|
|
|
|
debug "Generating initial proof", requestId = data.requestId
|
|
let challenge = await context.market.getChallenge(slot.id)
|
|
without proof =? (await onProve(slot, challenge)), err:
|
|
error "Failed to generate initial proof", error = err.msg
|
|
return some State(SaleErrored(error: err))
|
|
|
|
debug "Finished proof calculation", requestId = data.requestId
|
|
|
|
return some State(SaleFilling(proof: proof))
|