mirror of
https://github.com/status-im/nim-codex.git
synced 2025-01-09 18:36:29 +00:00
0c6784da7e
* nix: make derivation and update shell Create a structure for nix files. Add the derivation file which is using system Nim to compile Codex. Referenced issue: https://github.com/codex-storage/nim-codex/issues/940 Signed-off-by: markoburcul <marko@status.im> * nim-circom-compat: update Include commit which allows building circom-compat-ffi using Nix(doesn't affect current usage of the submodule). Referenced issue: https://github.com/codex-storage/nim-codex/issues/940 Signed-off-by: markoburcul <marko@status.im> * makefile: fix for detecting linux arch Signed-off-by: markoburcul <marko@status.im> --------- Signed-off-by: markoburcul <marko@status.im>
43 lines
1.3 KiB
Nix
43 lines
1.3 KiB
Nix
{
|
|
description = "Codex build flake";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
|
|
circom-compat.url = "github:codex-storage/circom-compat-ffi";
|
|
};
|
|
|
|
outputs = { self, nixpkgs, circom-compat}:
|
|
let
|
|
stableSystems = [
|
|
"x86_64-linux" "aarch64-linux"
|
|
"x86_64-darwin" "aarch64-darwin"
|
|
];
|
|
forAllSystems = f: nixpkgs.lib.genAttrs stableSystems (system: f system);
|
|
pkgsFor = forAllSystems (system: import nixpkgs { inherit system; });
|
|
in rec {
|
|
packages = forAllSystems (system: let
|
|
circomCompatPkg = circom-compat.packages.${system}.default;
|
|
buildTarget = pkgsFor.${system}.callPackage ./nix/default.nix {
|
|
inherit stableSystems circomCompatPkg;
|
|
src = self;
|
|
};
|
|
build = targets: buildTarget.override { inherit targets; };
|
|
in rec {
|
|
codex = build ["all"];
|
|
default = codex;
|
|
});
|
|
|
|
devShells = forAllSystems (system: let
|
|
pkgs = pkgsFor.${system};
|
|
in {
|
|
default = pkgs.mkShell {
|
|
inputsFrom = [
|
|
packages.${system}.codex
|
|
circom-compat.packages.${system}.default
|
|
];
|
|
# Not using buildInputs to override fakeGit and fakeCargo.
|
|
nativeBuildInputs = with pkgs; [ git cargo nodejs_18 ];
|
|
};
|
|
});
|
|
};
|
|
} |