mirror of
https://github.com/status-im/nim-codex.git
synced 2025-02-17 21:27:54 +00:00
15ff87a8bb
* fix: createReservation lock (#825) * fix: createReservation lock * fix: additional locking places * fix: acquire lock * chore: feedback Co-authored-by: markspanbroek <mark@spanbroek.net> Signed-off-by: Adam Uhlíř <adam@uhlir.dev> * feat: withLock template and fixed tests * fix: use proc for MockReservations constructor * chore: feedback Co-authored-by: Eric <5089238+emizzle@users.noreply.github.com> Signed-off-by: Adam Uhlíř <adam@uhlir.dev> * chore: feedback implementation --------- Signed-off-by: Adam Uhlíř <adam@uhlir.dev> Co-authored-by: markspanbroek <mark@spanbroek.net> Co-authored-by: Eric <5089238+emizzle@users.noreply.github.com> * Block deletion with ref count & repostore refactor (#631) * Fix StoreStream so it doesn't return parity bytes (#838) * fix storestream so it doesn\'t return parity bits for protected/verifiable manifests * use Cid.example instead of creating a mock manually * Fix verifiable manifest initialization (#839) * fix verifiable manifest initialization * fix linearstrategy, use verifiableStrategy to select blocks for slots * check for both strategies in attribute inheritance test * ci: add verify_circuit=true to the releases (#840) * provisional fix so EC errors do not crash the node on download (#841) --------- Signed-off-by: Adam Uhlíř <adam@uhlir.dev> Co-authored-by: Adam Uhlíř <adam@uhlir.dev> Co-authored-by: markspanbroek <mark@spanbroek.net> Co-authored-by: Eric <5089238+emizzle@users.noreply.github.com> Co-authored-by: Tomasz Bekas <tomasz.bekas@gmail.com> Co-authored-by: Giuliano Mega <giuliano.mega@gmail.com>
102 lines
2.9 KiB
Nim
102 lines
2.9 KiB
Nim
## Nim-Codex
|
|
## Copyright (c) 2023 Status Research & Development GmbH
|
|
## Licensed under either of
|
|
## * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE))
|
|
## * MIT license ([LICENSE-MIT](LICENSE-MIT))
|
|
## at your option.
|
|
## This file may not be copied, modified, or distributed except according to
|
|
## those terms.
|
|
|
|
## Store maintenance module
|
|
## Looks for and removes expired blocks from blockstores.
|
|
|
|
import pkg/chronos
|
|
import pkg/questionable
|
|
import pkg/questionable/results
|
|
|
|
import ./repostore
|
|
import ../utils/timer
|
|
import ../utils/asynciter
|
|
import ../clock
|
|
import ../logutils
|
|
import ../systemclock
|
|
|
|
const
|
|
DefaultBlockMaintenanceInterval* = 10.minutes
|
|
DefaultNumberOfBlocksToMaintainPerInterval* = 1000
|
|
|
|
type
|
|
BlockMaintainer* = ref object of RootObj
|
|
repoStore: RepoStore
|
|
interval: Duration
|
|
timer: Timer
|
|
clock: Clock
|
|
numberOfBlocksPerInterval: int
|
|
offset: int
|
|
|
|
proc new*(
|
|
T: type BlockMaintainer,
|
|
repoStore: RepoStore,
|
|
interval: Duration,
|
|
numberOfBlocksPerInterval = 100,
|
|
timer = Timer.new(),
|
|
clock: Clock = SystemClock.new()
|
|
): BlockMaintainer =
|
|
## Create new BlockMaintainer instance
|
|
##
|
|
## Call `start` to begin looking for for expired blocks
|
|
##
|
|
BlockMaintainer(
|
|
repoStore: repoStore,
|
|
interval: interval,
|
|
numberOfBlocksPerInterval: numberOfBlocksPerInterval,
|
|
timer: timer,
|
|
clock: clock,
|
|
offset: 0)
|
|
|
|
proc deleteExpiredBlock(self: BlockMaintainer, cid: Cid): Future[void] {.async.} =
|
|
if isErr (await self.repoStore.delBlock(cid)):
|
|
trace "Unable to delete block from repoStore"
|
|
|
|
proc processBlockExpiration(self: BlockMaintainer, be: BlockExpiration): Future[void] {.async} =
|
|
if be.expiry < self.clock.now:
|
|
await self.deleteExpiredBlock(be.cid)
|
|
else:
|
|
inc self.offset
|
|
|
|
proc runBlockCheck(self: BlockMaintainer): Future[void] {.async.} =
|
|
let expirations = await self.repoStore.getBlockExpirations(
|
|
maxNumber = self.numberOfBlocksPerInterval,
|
|
offset = self.offset
|
|
)
|
|
|
|
without iter =? expirations, err:
|
|
trace "Unable to obtain blockExpirations iterator from repoStore"
|
|
return
|
|
|
|
var numberReceived = 0
|
|
for beFut in iter:
|
|
let be = await beFut
|
|
inc numberReceived
|
|
await self.processBlockExpiration(be)
|
|
await sleepAsync(1.millis) # cooperative scheduling
|
|
|
|
# If we received fewer blockExpirations from the iterator than we asked for,
|
|
# We're at the end of the dataset and should start from 0 next time.
|
|
if numberReceived < self.numberOfBlocksPerInterval:
|
|
self.offset = 0
|
|
|
|
proc start*(self: BlockMaintainer) =
|
|
proc onTimer(): Future[void] {.async.} =
|
|
try:
|
|
await self.runBlockCheck()
|
|
except CancelledError as error:
|
|
raise error
|
|
except CatchableError as exc:
|
|
error "Unexpected exception in BlockMaintainer.onTimer(): ", msg=exc.msg
|
|
|
|
self.timer.start(onTimer, self.interval)
|
|
|
|
proc stop*(self: BlockMaintainer): Future[void] {.async.} =
|
|
await self.timer.stop()
|