mirror of
https://github.com/logos-storage/logos-storage-nim.git
synced 2026-01-05 23:13:09 +00:00
1cac3e2a11
* cleanup imports and logs * add BlockHandle type * revert deps * refactor: async error handling and future tracking improvements - Update async procedures to use explicit raises annotation - Modify TrackedFutures to handle futures with no raised exceptions - Replace `asyncSpawn` with explicit future tracking - Update test suites to use `unittest2` - Standardize error handling across network and async components - Remove deprecated error handling patterns This commit introduces a more robust approach to async error handling and future management, improving type safety and reducing potential runtime errors. * bump nim-serde * remove asyncSpawn * rework background downloads and prefetch * imporove logging * refactor: enhance async procedures with error handling and raise annotations * misc cleanup * misc * refactor: implement allFinishedFailed to aggregate future results with success and failure tracking * refactor: update error handling in reader procedures to raise ChunkerError and CancelledError * refactor: improve error handling in wantListHandler and accountHandler procedures * refactor: simplify LPStreamReadError creation by consolidating parameters * refactor: enhance error handling in AsyncStreamWrapper to catch unexpected errors * refactor: enhance error handling in advertiser and discovery loops to improve resilience * misc * refactor: improve code structure and readability * remove cancellation from addSlotToQueue * refactor: add assertion for unexpected errors in local store checks * refactor: prevent tracking of finished futures and improve test assertions * refactor: improve error handling in local store checks * remove usage of msgDetail * feat: add initial implementation of discovery engine and related components * refactor: improve task scheduling logic by removing unnecessary break statement * break after scheduling a task * make taskHandler cancelable * refactor: update async handlers to raise CancelledError * refactor(advertiser): streamline error handling and improve task flow in advertise loops * fix: correct spelling of "divisible" in error messages and comments * refactor(discovery): simplify discovery task loop and improve error handling * refactor(engine): filter peers before processing in cancelBlocks procedure
88 lines
2.5 KiB
Nim
88 lines
2.5 KiB
Nim
## Nim-Codex
|
|
## Copyright (c) 2022 Status Research & Development GmbH
|
|
## Licensed under either of
|
|
## * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE))
|
|
## * MIT license ([LICENSE-MIT](LICENSE-MIT))
|
|
## at your option.
|
|
## This file may not be copied, modified, or distributed except according to
|
|
## those terms.
|
|
|
|
{.push raises: [].}
|
|
|
|
import std/sequtils
|
|
import std/tables
|
|
import std/algorithm
|
|
import std/sequtils
|
|
|
|
import pkg/chronos
|
|
import pkg/libp2p
|
|
|
|
import ../protobuf/blockexc
|
|
import ../../blocktype
|
|
import ../../logutils
|
|
|
|
import ./peercontext
|
|
export peercontext
|
|
|
|
logScope:
|
|
topics = "codex peerctxstore"
|
|
|
|
type
|
|
PeerCtxStore* = ref object of RootObj
|
|
peers*: OrderedTable[PeerId, BlockExcPeerCtx]
|
|
|
|
PeersForBlock* = tuple[with: seq[BlockExcPeerCtx], without: seq[BlockExcPeerCtx]]
|
|
|
|
iterator items*(self: PeerCtxStore): BlockExcPeerCtx =
|
|
for p in self.peers.values:
|
|
yield p
|
|
|
|
proc contains*(a: openArray[BlockExcPeerCtx], b: PeerId): bool =
|
|
## Convenience method to check for peer precense
|
|
##
|
|
|
|
a.anyIt(it.id == b)
|
|
|
|
func peerIds*(self: PeerCtxStore): seq[PeerId] =
|
|
toSeq(self.peers.keys)
|
|
|
|
func contains*(self: PeerCtxStore, peerId: PeerId): bool =
|
|
peerId in self.peers
|
|
|
|
func add*(self: PeerCtxStore, peer: BlockExcPeerCtx) =
|
|
self.peers[peer.id] = peer
|
|
|
|
func remove*(self: PeerCtxStore, peerId: PeerId) =
|
|
self.peers.del(peerId)
|
|
|
|
func get*(self: PeerCtxStore, peerId: PeerId): BlockExcPeerCtx =
|
|
self.peers.getOrDefault(peerId, nil)
|
|
|
|
func len*(self: PeerCtxStore): int =
|
|
self.peers.len
|
|
|
|
func peersHave*(self: PeerCtxStore, address: BlockAddress): seq[BlockExcPeerCtx] =
|
|
toSeq(self.peers.values).filterIt(it.peerHave.anyIt(it == address))
|
|
|
|
func peersHave*(self: PeerCtxStore, cid: Cid): seq[BlockExcPeerCtx] =
|
|
toSeq(self.peers.values).filterIt(it.peerHave.anyIt(it.cidOrTreeCid == cid))
|
|
|
|
func peersWant*(self: PeerCtxStore, address: BlockAddress): seq[BlockExcPeerCtx] =
|
|
toSeq(self.peers.values).filterIt(it.peerWants.anyIt(it == address))
|
|
|
|
func peersWant*(self: PeerCtxStore, cid: Cid): seq[BlockExcPeerCtx] =
|
|
toSeq(self.peers.values).filterIt(it.peerWants.anyIt(it.address.cidOrTreeCid == cid))
|
|
|
|
proc getPeersForBlock*(self: PeerCtxStore, address: BlockAddress): PeersForBlock =
|
|
var res: PeersForBlock = (@[], @[])
|
|
for peer in self:
|
|
if peer.peerHave.anyIt(it == address):
|
|
res.with.add(peer)
|
|
else:
|
|
res.without.add(peer)
|
|
res
|
|
|
|
proc new*(T: type PeerCtxStore): PeerCtxStore =
|
|
## create new instance of a peer context store
|
|
PeerCtxStore(peers: initOrderedTable[PeerId, BlockExcPeerCtx]())
|