mirror of
https://github.com/logos-storage/logos-storage-nim.git
synced 2026-01-03 05:53:07 +00:00
28a83db69e
* Change token allowance method because increaseAllowance does not exist anymore * Returns collateral when a reservation is deleted and not only a slot is filled * Remove the returnedCollateral when the slot is not filled by the host * Add returnedCollateral when the sale is ignored * Add returnsCollateral variable for ignored state * Rebase the contracts submodule on the master * Add integration test * Fix duration * Remove unnecessary teardown function * Remove misleading comment * Get returned collateral from the request * Enable logs to debug on CI * Fix test * Increase test timeout * Fix typo * Fix rebase
64 lines
1.9 KiB
Nim
64 lines
1.9 KiB
Nim
import pkg/stint
|
|
import ../../logutils
|
|
import ../../market
|
|
import ../../utils/exceptions
|
|
import ../statemachine
|
|
import ../salesagent
|
|
import ./filled
|
|
import ./cancelled
|
|
import ./failed
|
|
import ./ignored
|
|
import ./errored
|
|
|
|
logScope:
|
|
topics = "marketplace sales filling"
|
|
|
|
type SaleFilling* = ref object of SaleState
|
|
proof*: Groth16Proof
|
|
|
|
method `$`*(state: SaleFilling): string =
|
|
"SaleFilling"
|
|
|
|
method onCancelled*(state: SaleFilling, request: StorageRequest): ?State =
|
|
return some State(SaleCancelled())
|
|
|
|
method onFailed*(state: SaleFilling, request: StorageRequest): ?State =
|
|
return some State(SaleFailed())
|
|
|
|
method run*(
|
|
state: SaleFilling, machine: Machine
|
|
): Future[?State] {.async: (raises: []).} =
|
|
let data = SalesAgent(machine).data
|
|
let market = SalesAgent(machine).context.market
|
|
|
|
without (request =? data.request):
|
|
raiseAssert "Request not set"
|
|
|
|
logScope:
|
|
requestId = data.requestId
|
|
slotIndex = data.slotIndex
|
|
|
|
try:
|
|
without collateral =? await market.slotCollateral(data.requestId, data.slotIndex),
|
|
err:
|
|
error "Failure attempting to fill slot: unable to calculate collateral",
|
|
error = err.msg
|
|
return some State(SaleErrored(error: err))
|
|
|
|
debug "Filling slot"
|
|
try:
|
|
await market.fillSlot(data.requestId, data.slotIndex, state.proof, collateral)
|
|
except SlotStateMismatchError as e:
|
|
debug "Slot is already filled, ignoring slot"
|
|
return some State(SaleIgnored(reprocessSlot: false, returnsCollateral: true))
|
|
except MarketError as e:
|
|
return some State(SaleErrored(error: e))
|
|
# other CatchableErrors are handled "automatically" by the SaleState
|
|
|
|
return some State(SaleFilled())
|
|
except CancelledError as e:
|
|
trace "SaleFilling.run was cancelled", error = e.msgDetail
|
|
except CatchableError as e:
|
|
error "Error during SaleFilling.run", error = e.msgDetail
|
|
return some State(SaleErrored(error: e))
|