mirror of
https://github.com/logos-storage/logos-storage-nim.git
synced 2026-01-02 13:33:10 +00:00
7deeb7d2b3
* Add availability enabled parameter * Return bytes to availability when finished * Add until parameter * Remove debug message * Clean up and fix tests * Update documentations and cleanup * Avoid swallowing CancelledError * Move until validation to reservations module * Call onAvailabilityAdded callabck when the availability is enabled in sales * Remove until validation in restapi when creating an availability * Add openapi documentation * Use results instead of stew/results (#1112) * feat: request duration limit (#1057) * feat: request duration limit * Fix tests and duration type * Add custom error * Remove merge issue * Update codex contracts eth * Update market config and fix test * Fix SlotReservationsConfig syntax * Update dependencies * test: remove doubled test * chore: update contracts repo --------- Co-authored-by: Arnaud <arnaud@status.im> * fix(statemachine): do not raise from state.run (#1115) * fix(statemachine): do not raise from state.run * fix rebase * fix exception handling in SaleProvingSimulated.prove - re-raise CancelledError - don't return State on CatchableError - expect the Proofs_InvalidProof custom error instead of checking a string * asyncSpawn salesagent.onCancelled This was swallowing a KeyError in one of the tests (fixed in the previous commit) * remove error handling states in asyncstatemachine * revert unneeded changes * formatting * PR feedback, logging updates * chore(integration): simplify block expiration integration test (#1100) * chore(integration): simplify block expiration integration test * clean up * fix after rebase * perf: contract storage optimizations (#1094) * perf: contract storage optimizations * Apply optimization changes * Apply optimizing parameters sizing * Update codex-contracts-eth * bump latest changes in contracts branch * Change requestDurationLimit to uint64 * fix tests * fix tests --------- Co-authored-by: Arnaud <arnaud@status.im> Co-authored-by: Eric <5089238+emizzle@users.noreply.github.com> * bump contracts to master (#1122) * Add availability enabled parameter * Return bytes to availability when finished * Add until parameter * Clean up and fix tests * Move until validation to reservations module * Apply suggestion changes: return the reservation module error * Apply suggestion changes for until dates * Apply suggestion changes: reorganize tests * Fix indent * Remove test related to timing issue * Add raises errors to async pragram and remove useless try except * Update open api documentation * Fix wording * Remove the httpClient restart statements * Use market.getRequestEnd to set validUntil * Remove returnBytes * Use clock.now in testing * Move the api validation file to the right file --------- Co-authored-by: Adam Uhlíř <adam@uhlir.dev> Co-authored-by: Eric <5089238+emizzle@users.noreply.github.com>
120 lines
3.9 KiB
Nim
120 lines
3.9 KiB
Nim
import pkg/chronos
|
|
import pkg/questionable
|
|
import pkg/datastore
|
|
import pkg/codex/contracts/requests
|
|
import pkg/codex/sales/states/preparing
|
|
import pkg/codex/sales/states/slotreserving
|
|
import pkg/codex/sales/states/cancelled
|
|
import pkg/codex/sales/states/failed
|
|
import pkg/codex/sales/states/filled
|
|
import pkg/codex/sales/states/ignored
|
|
import pkg/codex/sales/states/errored
|
|
import pkg/codex/sales/salesagent
|
|
import pkg/codex/sales/salescontext
|
|
import pkg/codex/sales/reservations
|
|
import pkg/codex/stores/repostore
|
|
import times
|
|
import ../../../asynctest
|
|
import ../../helpers
|
|
import ../../examples
|
|
import ../../helpers/mockmarket
|
|
import ../../helpers/mockreservations
|
|
import ../../helpers/mockclock
|
|
|
|
asyncchecksuite "sales state 'preparing'":
|
|
let request = StorageRequest.example
|
|
let slotIndex = request.ask.slots div 2
|
|
let market = MockMarket.new()
|
|
let clock = MockClock.new()
|
|
var agent: SalesAgent
|
|
var state: SalePreparing
|
|
var repo: RepoStore
|
|
var availability: Availability
|
|
var context: SalesContext
|
|
var reservations: MockReservations
|
|
|
|
setup:
|
|
availability = Availability.init(
|
|
totalSize = request.ask.slotSize + 100.uint64,
|
|
freeSize = request.ask.slotSize + 100.uint64,
|
|
duration = request.ask.duration + 60.uint64,
|
|
minPricePerBytePerSecond = request.ask.pricePerBytePerSecond,
|
|
totalCollateral = request.ask.collateralPerSlot * request.ask.slots.u256,
|
|
enabled = true,
|
|
until = 0.SecondsSince1970,
|
|
)
|
|
let repoDs = SQLiteDatastore.new(Memory).tryGet()
|
|
let metaDs = SQLiteDatastore.new(Memory).tryGet()
|
|
repo = RepoStore.new(repoDs, metaDs)
|
|
await repo.start()
|
|
|
|
state = SalePreparing.new()
|
|
context = SalesContext(market: market, clock: clock)
|
|
|
|
reservations = MockReservations.new(repo)
|
|
context.reservations = reservations
|
|
agent = newSalesAgent(context, request.id, slotIndex, request.some)
|
|
|
|
market.requestEnds[request.id] = clock.now() + cast[int64](request.ask.duration)
|
|
|
|
teardown:
|
|
await repo.stop()
|
|
|
|
test "switches to cancelled state when request expires":
|
|
let next = state.onCancelled(request)
|
|
check !next of SaleCancelled
|
|
|
|
test "switches to failed state when request fails":
|
|
let next = state.onFailed(request)
|
|
check !next of SaleFailed
|
|
|
|
test "switches to filled state when slot is filled":
|
|
let next = state.onSlotFilled(request.id, slotIndex)
|
|
check !next of SaleFilled
|
|
|
|
proc createAvailability(enabled = true) {.async.} =
|
|
let a = await reservations.createAvailability(
|
|
availability.totalSize,
|
|
availability.duration,
|
|
availability.minPricePerBytePerSecond,
|
|
availability.totalCollateral,
|
|
enabled,
|
|
until = 0.SecondsSince1970,
|
|
)
|
|
availability = a.get
|
|
|
|
test "run switches to ignored when no availability":
|
|
let next = !(await state.run(agent))
|
|
check next of SaleIgnored
|
|
let ignored = SaleIgnored(next)
|
|
check ignored.reprocessSlot
|
|
|
|
test "run switches to ignored when availability is not enabled":
|
|
await createAvailability(enabled = false)
|
|
let next = !(await state.run(agent))
|
|
check next of SaleIgnored
|
|
|
|
test "run switches to slot reserving state after reservation created":
|
|
await createAvailability()
|
|
let next = await state.run(agent)
|
|
check !next of SaleSlotReserving
|
|
|
|
test "run switches to ignored when reserve fails with BytesOutOfBounds":
|
|
await createAvailability()
|
|
reservations.setCreateReservationThrowBytesOutOfBoundsError(true)
|
|
|
|
let next = !(await state.run(agent))
|
|
check next of SaleIgnored
|
|
let ignored = SaleIgnored(next)
|
|
check ignored.reprocessSlot
|
|
|
|
test "run switches to errored when reserve fails with other error":
|
|
await createAvailability()
|
|
let error = newException(CatchableError, "some error")
|
|
reservations.setCreateReservationThrowError(some error)
|
|
|
|
let next = !(await state.run(agent))
|
|
check next of SaleErrored
|
|
let errored = SaleErrored(next)
|
|
check errored.error == error
|