mirror of
https://github.com/logos-storage/logos-storage-nim.git
synced 2026-01-02 13:33:10 +00:00
1cac3e2a11
* cleanup imports and logs * add BlockHandle type * revert deps * refactor: async error handling and future tracking improvements - Update async procedures to use explicit raises annotation - Modify TrackedFutures to handle futures with no raised exceptions - Replace `asyncSpawn` with explicit future tracking - Update test suites to use `unittest2` - Standardize error handling across network and async components - Remove deprecated error handling patterns This commit introduces a more robust approach to async error handling and future management, improving type safety and reducing potential runtime errors. * bump nim-serde * remove asyncSpawn * rework background downloads and prefetch * imporove logging * refactor: enhance async procedures with error handling and raise annotations * misc cleanup * misc * refactor: implement allFinishedFailed to aggregate future results with success and failure tracking * refactor: update error handling in reader procedures to raise ChunkerError and CancelledError * refactor: improve error handling in wantListHandler and accountHandler procedures * refactor: simplify LPStreamReadError creation by consolidating parameters * refactor: enhance error handling in AsyncStreamWrapper to catch unexpected errors * refactor: enhance error handling in advertiser and discovery loops to improve resilience * misc * refactor: improve code structure and readability * remove cancellation from addSlotToQueue * refactor: add assertion for unexpected errors in local store checks * refactor: prevent tracking of finished futures and improve test assertions * refactor: improve error handling in local store checks * remove usage of msgDetail * feat: add initial implementation of discovery engine and related components * refactor: improve task scheduling logic by removing unnecessary break statement * break after scheduling a task * make taskHandler cancelable * refactor: update async handlers to raise CancelledError * refactor(advertiser): streamline error handling and improve task flow in advertise loops * fix: correct spelling of "divisible" in error messages and comments * refactor(discovery): simplify discovery task loop and improve error handling * refactor(engine): filter peers before processing in cancelBlocks procedure
108 lines
3.2 KiB
Nim
108 lines
3.2 KiB
Nim
## Nim-Codex
|
|
## Copyright (c) 2021 Status Research & Development GmbH
|
|
## Licensed under either of
|
|
## * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE))
|
|
## * MIT license ([LICENSE-MIT](LICENSE-MIT))
|
|
## at your option.
|
|
## This file may not be copied, modified, or distributed except according to
|
|
## those terms.
|
|
|
|
{.push raises: [].}
|
|
|
|
import pkg/chronos
|
|
import pkg/libp2p
|
|
|
|
import ../protobuf/blockexc
|
|
import ../protobuf/message
|
|
import ../../errors
|
|
import ../../logutils
|
|
import ../../utils/trackedfutures
|
|
|
|
logScope:
|
|
topics = "codex blockexcnetworkpeer"
|
|
|
|
const DefaultYieldInterval = 50.millis
|
|
|
|
type
|
|
ConnProvider* =
|
|
proc(): Future[Connection] {.gcsafe, async: (raises: [CancelledError]).}
|
|
|
|
RPCHandler* = proc(peer: NetworkPeer, msg: Message) {.gcsafe, async: (raises: []).}
|
|
|
|
NetworkPeer* = ref object of RootObj
|
|
id*: PeerId
|
|
handler*: RPCHandler
|
|
sendConn: Connection
|
|
getConn: ConnProvider
|
|
yieldInterval*: Duration = DefaultYieldInterval
|
|
trackedFutures: TrackedFutures
|
|
|
|
proc connected*(self: NetworkPeer): bool =
|
|
not (isNil(self.sendConn)) and not (self.sendConn.closed or self.sendConn.atEof)
|
|
|
|
proc readLoop*(self: NetworkPeer, conn: Connection) {.async: (raises: []).} =
|
|
if isNil(conn):
|
|
trace "No connection to read from", peer = self.id
|
|
return
|
|
|
|
trace "Attaching read loop", peer = self.id, connId = conn.oid
|
|
try:
|
|
var nextYield = Moment.now() + self.yieldInterval
|
|
while not conn.atEof or not conn.closed:
|
|
if Moment.now() > nextYield:
|
|
nextYield = Moment.now() + self.yieldInterval
|
|
trace "Yielding in read loop",
|
|
peer = self.id, nextYield = nextYield, interval = self.yieldInterval
|
|
await sleepAsync(10.millis)
|
|
|
|
let
|
|
data = await conn.readLp(MaxMessageSize.int)
|
|
msg = Message.protobufDecode(data).mapFailure().tryGet()
|
|
trace "Received message", peer = self.id, connId = conn.oid
|
|
await self.handler(self, msg)
|
|
except CancelledError:
|
|
trace "Read loop cancelled"
|
|
except CatchableError as err:
|
|
warn "Exception in blockexc read loop", msg = err.msg
|
|
finally:
|
|
trace "Detaching read loop", peer = self.id, connId = conn.oid
|
|
await conn.close()
|
|
|
|
proc connect*(
|
|
self: NetworkPeer
|
|
): Future[Connection] {.async: (raises: [CancelledError]).} =
|
|
if self.connected:
|
|
trace "Already connected", peer = self.id, connId = self.sendConn.oid
|
|
return self.sendConn
|
|
|
|
self.sendConn = await self.getConn()
|
|
self.trackedFutures.track(self.readLoop(self.sendConn))
|
|
return self.sendConn
|
|
|
|
proc send*(
|
|
self: NetworkPeer, msg: Message
|
|
) {.async: (raises: [CancelledError, LPStreamError]).} =
|
|
let conn = await self.connect()
|
|
|
|
if isNil(conn):
|
|
warn "Unable to get send connection for peer message not sent", peer = self.id
|
|
return
|
|
|
|
trace "Sending message", peer = self.id, connId = conn.oid
|
|
await conn.writeLp(protobufEncode(msg))
|
|
|
|
func new*(
|
|
T: type NetworkPeer,
|
|
peer: PeerId,
|
|
connProvider: ConnProvider,
|
|
rpcHandler: RPCHandler,
|
|
): NetworkPeer =
|
|
doAssert(not isNil(connProvider), "should supply connection provider")
|
|
|
|
NetworkPeer(
|
|
id: peer,
|
|
getConn: connProvider,
|
|
handler: rpcHandler,
|
|
trackedFutures: TrackedFutures(),
|
|
)
|