mirror of
https://github.com/logos-messaging/nim-sds.git
synced 2026-02-16 20:13:23 +00:00
0dea35d364
Changes include: - Removing all submodules from vendor folder. - Updating sds.nimble with required depndencies. - Generating a nimble.lock file using Nimble. - Updated Nim code to reference depndencies correctly. - Added nix/deps.nix fixed output derivation that calls Nimble. - Updated nixpkgs to use 25.11 commit which provides Nimbe 0.20.1. - Disabled Nix Android builds on MacOS due to Nimble segfault. Signed-off-by: Jakub Sokołowski <jakub@status.im>
78 lines
2.1 KiB
Nix
78 lines
2.1 KiB
Nix
{
|
|
description = "Nim-SDS build flake";
|
|
|
|
nixConfig = {
|
|
extra-substituters = [ "https://nix-cache.status.im/" ];
|
|
extra-trusted-public-keys = [ "nix-cache.status.im-1:x/93lOfLU+duPplwMSBR+OlY4+mo+dCN7n0mr4oPwgY=" ];
|
|
};
|
|
|
|
inputs = {
|
|
# We are pinning the commit because ultimately we want to use same commit across different projects.
|
|
# A commit from nixpkgs 25.11 release : https://github.com/NixOS/nixpkgs/tree/release-25.11
|
|
nixpkgs.url = "github:NixOS/nixpkgs?rev=23d72dabcb3b12469f57b37170fcbc1789bd7457";
|
|
};
|
|
|
|
outputs = { self, nixpkgs }:
|
|
let
|
|
stableSystems = [
|
|
"x86_64-linux" "aarch64-linux"
|
|
"x86_64-darwin" "aarch64-darwin"
|
|
"x86_64-windows"
|
|
];
|
|
|
|
forAllSystems = f: nixpkgs.lib.genAttrs stableSystems (system: f system);
|
|
|
|
pkgsFor = forAllSystems (
|
|
system: import nixpkgs {
|
|
inherit system;
|
|
config = {
|
|
android_sdk.accept_license = true;
|
|
allowUnfree = true;
|
|
};
|
|
overlays = [
|
|
(final: prev: {
|
|
androidEnvCustom = prev.callPackage ./nix/pkgs/android-sdk { };
|
|
androidPkgs = final.androidEnvCustom.pkgs;
|
|
androidShell = final.androidEnvCustom.shell;
|
|
})
|
|
];
|
|
}
|
|
);
|
|
|
|
in rec {
|
|
packages = forAllSystems (system: let
|
|
pkgs = pkgsFor.${system};
|
|
|
|
buildTargets = pkgs.callPackage ./nix/default.nix {
|
|
src = self;
|
|
};
|
|
|
|
# All potential targets
|
|
allTargets = [
|
|
"libsds"
|
|
"libsds-android-arm64"
|
|
"libsds-android-amd64"
|
|
"libsds-android-x86"
|
|
"libsds-android-arm"
|
|
"libsds-ios"
|
|
];
|
|
|
|
# Create a package for each target
|
|
allPackages = builtins.listToAttrs (map (t: {
|
|
name = t;
|
|
value = buildTargets.override { targets = [ t ]; };
|
|
}) allTargets);
|
|
in
|
|
allPackages // {
|
|
default = allPackages.libsds;
|
|
}
|
|
);
|
|
|
|
devShells = forAllSystems (system: {
|
|
default = pkgsFor.${system}.callPackage ./nix/shell.nix {
|
|
};
|
|
});
|
|
};
|
|
|
|
}
|