mirror of
https://github.com/logos-messaging/logos-messaging-nim.git
synced 2026-02-13 02:13:12 +00:00
1fd25355e0
* Introduce api/send Added events and requests for support. Reworked delivery_monitor into a featured devlivery_service, that - supports relay publish and lightpush depending on configuration but with fallback options - if available and configured it utilizes store api to confirm message delivery - emits message delivery events accordingly prepare for use in api_example * Fix edge mode config and test added * Fix some import issues, start and stop waku shall not throw exception but return with result properly * Utlize sync RequestBroker, adapt to non-async broker usage and gcsafe where appropriate, removed leftover * add api_example app to examples2 * Adapt after merge from master * Adapt code for using broker context * Fix brokerCtx settings for all usedbrokers, cover locked node init * Various fixes upon test failures. Added initial of subscribe API and auto-subscribe for send api * More test added * Fix multi propagate event emit, fix fail send test case * Fix rebase * Fix PushMessageHandlers in tests * adapt libwaku to api changes * Fix relay test by adapting publish return error in case NoPeersToPublish * Addressing all remaining review findings. Removed leftovers. Fixed loggings and typos * Fix rln relay broker, missed brokerCtx * Fix rest relay test failed, due to publish will fail if no peer avail * ignore anvil test state file * Make terst_wakunode_rln_relay broker context aware to fix * Fix waku rln tests by having them broker context aware * fix typo in test_app.nim
82 lines
2.8 KiB
Nim
82 lines
2.8 KiB
Nim
import chronicles, chronos, results
|
|
import std/options
|
|
|
|
import
|
|
waku/node/peer_manager,
|
|
waku/waku_core,
|
|
waku/waku_lightpush/[common, client, rpc],
|
|
waku/common/broker/broker_context
|
|
|
|
import ./[delivery_task, send_processor]
|
|
|
|
logScope:
|
|
topics = "send service lightpush processor"
|
|
|
|
type LightpushSendProcessor* = ref object of BaseSendProcessor
|
|
peerManager: PeerManager
|
|
lightpushClient: WakuLightPushClient
|
|
|
|
proc new*(
|
|
T: typedesc[LightpushSendProcessor],
|
|
peerManager: PeerManager,
|
|
lightpushClient: WakuLightPushClient,
|
|
brokerCtx: BrokerContext,
|
|
): T =
|
|
return
|
|
T(peerManager: peerManager, lightpushClient: lightpushClient, brokerCtx: brokerCtx)
|
|
|
|
proc isLightpushPeerAvailable(
|
|
self: LightpushSendProcessor, pubsubTopic: PubsubTopic
|
|
): bool =
|
|
return self.peerManager.selectPeer(WakuLightPushCodec, some(pubsubTopic)).isSome()
|
|
|
|
method isValidProcessor*(
|
|
self: LightpushSendProcessor, task: DeliveryTask
|
|
): bool {.gcsafe.} =
|
|
return self.isLightpushPeerAvailable(task.pubsubTopic)
|
|
|
|
method sendImpl*(
|
|
self: LightpushSendProcessor, task: DeliveryTask
|
|
): Future[void] {.async.} =
|
|
task.tryCount.inc()
|
|
info "Trying message delivery via Lightpush",
|
|
requestId = task.requestId,
|
|
msgHash = task.msgHash.to0xHex(),
|
|
tryCount = task.tryCount
|
|
|
|
let peer = self.peerManager.selectPeer(WakuLightPushCodec, some(task.pubsubTopic)).valueOr:
|
|
debug "No peer available for Lightpush, request pushed back for next round",
|
|
requestId = task.requestId
|
|
task.state = DeliveryState.NextRoundRetry
|
|
return
|
|
|
|
let numLightpushServers = (
|
|
await self.lightpushClient.publish(some(task.pubsubTopic), task.msg, peer)
|
|
).valueOr:
|
|
error "LightpushSendProcessor.sendImpl failed", error = error.desc.get($error.code)
|
|
case error.code
|
|
of LightPushErrorCode.NO_PEERS_TO_RELAY, LightPushErrorCode.TOO_MANY_REQUESTS,
|
|
LightPushErrorCode.OUT_OF_RLN_PROOF, LightPushErrorCode.SERVICE_NOT_AVAILABLE,
|
|
LightPushErrorCode.INTERNAL_SERVER_ERROR:
|
|
task.state = DeliveryState.NextRoundRetry
|
|
else:
|
|
# the message is malformed, send error
|
|
task.state = DeliveryState.FailedToDeliver
|
|
task.errorDesc = error.desc.get($error.code)
|
|
task.deliveryTime = Moment.now()
|
|
return
|
|
|
|
if numLightpushServers > 0:
|
|
info "Message propagated via Lightpush",
|
|
requestId = task.requestId, msgHash = task.msgHash.to0xHex()
|
|
task.state = DeliveryState.SuccessfullyPropagated
|
|
task.deliveryTime = Moment.now()
|
|
# TODO: with a simple retry processor it might be more accurate to say `Sent`
|
|
else:
|
|
# Controversial state, publish says ok but no peer. It should not happen.
|
|
debug "Lightpush publish returned zero peers, request pushed back for next round",
|
|
requestId = task.requestId
|
|
task.state = DeliveryState.NextRoundRetry
|
|
|
|
return
|