mirror of
https://github.com/logos-messaging/logos-messaging-nim.git
synced 2026-06-18 07:29:34 +00:00
6837ae0c1f
* bump nim-libp2p pin to v2.0.0 tag * bump json_rpc to v0.6.1, lsquic to v0.5.1, boringssl to v0.0.8 (latest tags) * add libp2p_mix dep; repoint libp2p/protocols/mix -> libp2p_mix * pin nimble.lock: websock / protobuf_serialization / npeg / jwt * Makefile: add -d:libp2p_quic_support * regenerate nix/deps.nix (adds libp2p_mix, refreshes pins) * migrate rng ref HmacDrbgContext -> libp2p Rng across prod/channels/tests (interface-only; same DRBG) * waku_switch: TransportConfig factory; unified 2.0.0 connection limits (withMaxInOut, withMaxConnections); local MaxConnections * waku_relay/rendezvous/discv5/kademlia: v2.0.0 API (rng, config, ServiceDiscovery rename) * call Service.setup() on post-build switch services (2.0.0 split setup/start) * drop libp2p/utils/semaphore -> chronos AsyncSemaphore * add logos_delivery/waku/compat/option_valueor shim (Option[T] valueOr/withValue, dropped upstream) * add std/options where a transitive re-export was removed * add newStandardSwitch shim (libp2p removed it in 2.0.0); mounts yamux+mplex to match prod muxer * PeerId.random(rng); common.rng()/crypto.newRng(); hoist shared rng (instantiation cleanup) * update expectations for 2.0.0 defaults: DEFAULT_PROTOCOLS += /ipfs/id/push/1.0.0; agent "nim-libp2p" * drop relay reboot/reconnect test (asserted a Switch restart capability that is simply not supported) * fix up a few tests that were flaking on MacOS (libp2p upgrade may have exposed these)
113 lines
4.0 KiB
Nim
113 lines
4.0 KiB
Nim
import logos_delivery/waku/compat/option_valueor
|
|
import std/[atomics, options, macros]
|
|
import chronicles, chronos, chronos/threadsync, ffi
|
|
import
|
|
logos_delivery/waku/waku_core/message/message,
|
|
logos_delivery/waku/waku_core/topics/pubsub_topic,
|
|
logos_delivery/waku/waku_relay,
|
|
logos_delivery/waku/factory/waku,
|
|
logos_delivery/waku/node/waku_node,
|
|
logos_delivery/waku/node/health_monitor/health_status,
|
|
../logos_delivery/waku/factory/app_callbacks,
|
|
./events/json_message_event,
|
|
./events/json_topic_health_change_event,
|
|
./events/json_connection_change_event,
|
|
./events/json_connection_status_change_event,
|
|
./declare_lib
|
|
|
|
################################################################################
|
|
## Include different APIs, i.e. all procs with {.ffi.} pragma
|
|
|
|
include
|
|
./logos_delivery_api/node_api,
|
|
./logos_delivery_api/messaging_api,
|
|
./logos_delivery_api/debug_api,
|
|
./kernel_api/peer_manager_api,
|
|
./kernel_api/discovery_api,
|
|
./kernel_api/node_lifecycle_api,
|
|
./kernel_api/debug_node_api,
|
|
./kernel_api/ping_api,
|
|
./kernel_api/protocols/relay_api,
|
|
./kernel_api/protocols/store_api,
|
|
./kernel_api/protocols/lightpush_api,
|
|
./kernel_api/protocols/filter_api
|
|
|
|
################################################################################
|
|
### Exported procs (former libwaku API)
|
|
|
|
proc waku_new(
|
|
configJson: cstring, callback: FFICallback, userData: pointer
|
|
): pointer {.dynlib, exportc, cdecl.} =
|
|
initializeLibrary()
|
|
|
|
## Creates a new instance of the WakuNode.
|
|
if isNil(callback):
|
|
echo "error: missing callback in waku_new"
|
|
return nil
|
|
|
|
## Create the Waku thread that will keep waiting for req from the main thread.
|
|
var ctx = ffi.createFFIContext[Waku]().valueOr:
|
|
let msg = "Error in createFFIContext: " & $error
|
|
callback(RET_ERR, unsafeAddr msg[0], cast[csize_t](len(msg)), userData)
|
|
return nil
|
|
|
|
ctx.userData = userData
|
|
|
|
proc onReceivedMessage(ctx: ptr FFIContext): WakuRelayHandler =
|
|
return proc(pubsubTopic: PubsubTopic, msg: WakuMessage) {.async.} =
|
|
callEventCallback(ctx, "onReceivedMessage"):
|
|
$JsonMessageEvent.new(pubsubTopic, msg)
|
|
|
|
proc onTopicHealthChange(ctx: ptr FFIContext): TopicHealthChangeHandler =
|
|
return proc(pubsubTopic: PubsubTopic, topicHealth: TopicHealth) {.async.} =
|
|
callEventCallback(ctx, "onTopicHealthChange"):
|
|
$JsonTopicHealthChangeEvent.new(pubsubTopic, topicHealth)
|
|
|
|
proc onConnectionChange(ctx: ptr FFIContext): ConnectionChangeHandler =
|
|
return proc(peerId: PeerId, peerEvent: PeerEventKind) {.async.} =
|
|
callEventCallback(ctx, "onConnectionChange"):
|
|
$JsonConnectionChangeEvent.new($peerId, peerEvent)
|
|
|
|
proc onConnectionStatusChange(ctx: ptr FFIContext): ConnectionStatusChangeHandler =
|
|
return proc(status: ConnectionStatus) {.async.} =
|
|
callEventCallback(ctx, "onConnectionStatusChange"):
|
|
$JsonConnectionStatusChangeEvent.new(status)
|
|
|
|
let appCallbacks = AppCallbacks(
|
|
relayHandler: onReceivedMessage(ctx),
|
|
topicHealthChangeHandler: onTopicHealthChange(ctx),
|
|
connectionChangeHandler: onConnectionChange(ctx),
|
|
connectionStatusChangeHandler: onConnectionStatusChange(ctx),
|
|
)
|
|
|
|
ffi.sendRequestToFFIThread(
|
|
ctx,
|
|
CreateNodeWithCallbacksRequest.ffiNewReq(
|
|
callback, userData, configJson, appCallbacks
|
|
),
|
|
).isOkOr:
|
|
let msg = "error in sendRequestToFFIThread: " & $error
|
|
callback(RET_ERR, unsafeAddr msg[0], cast[csize_t](len(msg)), userData)
|
|
return nil
|
|
|
|
return ctx
|
|
|
|
proc waku_destroy(
|
|
ctx: ptr FFIContext[Waku], callback: FFICallBack, userData: pointer
|
|
): cint {.dynlib, exportc, cdecl.} =
|
|
initializeLibrary()
|
|
checkParams(ctx, callback, userData)
|
|
|
|
ffi.destroyFFIContext(ctx).isOkOr:
|
|
let msg = "libwaku error: " & $error
|
|
callback(RET_ERR, unsafeAddr msg[0], cast[csize_t](len(msg)), userData)
|
|
return RET_ERR
|
|
|
|
## always need to invoke the callback although we don't retrieve value to the caller
|
|
callback(RET_OK, nil, 0, userData)
|
|
|
|
return RET_OK
|
|
|
|
# ### End of exported procs
|
|
# ################################################################################
|