mirror of
https://github.com/logos-messaging/logos-messaging-nim.git
synced 2026-06-26 11:29:28 +00:00
6837ae0c1f
* bump nim-libp2p pin to v2.0.0 tag * bump json_rpc to v0.6.1, lsquic to v0.5.1, boringssl to v0.0.8 (latest tags) * add libp2p_mix dep; repoint libp2p/protocols/mix -> libp2p_mix * pin nimble.lock: websock / protobuf_serialization / npeg / jwt * Makefile: add -d:libp2p_quic_support * regenerate nix/deps.nix (adds libp2p_mix, refreshes pins) * migrate rng ref HmacDrbgContext -> libp2p Rng across prod/channels/tests (interface-only; same DRBG) * waku_switch: TransportConfig factory; unified 2.0.0 connection limits (withMaxInOut, withMaxConnections); local MaxConnections * waku_relay/rendezvous/discv5/kademlia: v2.0.0 API (rng, config, ServiceDiscovery rename) * call Service.setup() on post-build switch services (2.0.0 split setup/start) * drop libp2p/utils/semaphore -> chronos AsyncSemaphore * add logos_delivery/waku/compat/option_valueor shim (Option[T] valueOr/withValue, dropped upstream) * add std/options where a transitive re-export was removed * add newStandardSwitch shim (libp2p removed it in 2.0.0); mounts yamux+mplex to match prod muxer * PeerId.random(rng); common.rng()/crypto.newRng(); hoist shared rng (instantiation cleanup) * update expectations for 2.0.0 defaults: DEFAULT_PROTOCOLS += /ipfs/id/push/1.0.0; agent "nim-libp2p" * drop relay reboot/reconnect test (asserted a Switch restart capability that is simply not supported) * fix up a few tests that were flaking on MacOS (libp2p upgrade may have exposed these)
119 lines
3.6 KiB
Nim
119 lines
3.6 KiB
Nim
import libp2p/crypto/rng
|
|
{.used.}
|
|
|
|
import
|
|
std/[sequtils, tables],
|
|
results,
|
|
stew/base32,
|
|
testutils/unittests,
|
|
chronicles,
|
|
chronos,
|
|
libp2p/crypto/crypto,
|
|
eth/keys,
|
|
dnsdisc/builder
|
|
import
|
|
logos_delivery/waku/node/peer_manager,
|
|
logos_delivery/waku/waku_node,
|
|
logos_delivery/waku/discovery/waku_dnsdisc,
|
|
./testlib/common,
|
|
./testlib/wakucore,
|
|
./testlib/wakunode
|
|
|
|
suite "Waku DNS Discovery":
|
|
asyncTest "Waku DNS Discovery end-to-end":
|
|
## Tests integrated DNS discovery, from building
|
|
## the tree to connecting to discovered nodes
|
|
|
|
# Create nodes and ENR. These will be added to the discoverable list
|
|
let
|
|
bindIp = parseIpAddress("0.0.0.0")
|
|
nodeKey1 = generateSecp256k1Key()
|
|
node1 = newTestWakuNode(nodeKey1, bindIp, Port(63500))
|
|
enr1 = node1.enr
|
|
nodeKey2 = generateSecp256k1Key()
|
|
node2 = newTestWakuNode(nodeKey2, bindIp, Port(63502))
|
|
enr2 = node2.enr
|
|
nodeKey3 = generateSecp256k1Key()
|
|
node3 = newTestWakuNode(nodeKey3, bindIp, Port(63503))
|
|
enr3 = node3.enr
|
|
|
|
(await node1.mountRelay()).isOkOr:
|
|
assert false, "Failed to mount relay"
|
|
(await node2.mountRelay()).isOkOr:
|
|
assert false, "Failed to mount relay"
|
|
(await node3.mountRelay()).isOkOr:
|
|
assert false, "Failed to mount relay"
|
|
await allFutures([node1.start(), node2.start(), node3.start()])
|
|
|
|
# Build and sign tree
|
|
var tree = buildTree(
|
|
1, # Seq no
|
|
@[enr1, enr2, enr3], # ENR entries
|
|
@[],
|
|
)
|
|
.get() # No link entries
|
|
|
|
let treeKeys = keys.KeyPair.random(keys.newRng()[])
|
|
|
|
# Sign tree
|
|
check:
|
|
tree.signTree(treeKeys.seckey()).isOk()
|
|
|
|
# Create TXT records at domain
|
|
let
|
|
domain = "testnodes.aq"
|
|
zoneTxts = tree.buildTXT(domain).get()
|
|
username = Base32.encode(treeKeys.pubkey().toRawCompressed())
|
|
location = LinkPrefix & username & "@" & domain
|
|
# See EIP-1459: https://eips.ethereum.org/EIPS/eip-1459
|
|
|
|
# Create a resolver for the domain
|
|
|
|
proc resolver(domain: string): Future[string] {.async, gcsafe.} =
|
|
return zoneTxts[domain]
|
|
|
|
# Create Waku DNS discovery client on a new Waku v2 node using the resolver
|
|
|
|
let
|
|
nodeKey4 = generateSecp256k1Key()
|
|
node4 = newTestWakuNode(nodeKey4, bindIp, Port(63504))
|
|
|
|
(await node4.mountRelay()).isOkOr:
|
|
assert false, "Failed to mount relay"
|
|
await node4.start()
|
|
|
|
var wakuDnsDisc = WakuDnsDiscovery.init(location, resolver).get()
|
|
|
|
let res = await wakuDnsDisc.findPeers()
|
|
|
|
check:
|
|
# We have discovered all three nodes
|
|
res.isOk()
|
|
res[].len == 3
|
|
res[].mapIt(it.peerId).contains(node1.switch.peerInfo.peerId)
|
|
res[].mapIt(it.peerId).contains(node2.switch.peerInfo.peerId)
|
|
res[].mapIt(it.peerId).contains(node3.switch.peerInfo.peerId)
|
|
|
|
# Connect to discovered nodes
|
|
await node4.connectToNodes(res[])
|
|
|
|
check:
|
|
# We have successfully connected to all discovered nodes
|
|
node4.peerManager.switch.peerStore.peers().anyIt(
|
|
it.peerId == node1.switch.peerInfo.peerId
|
|
)
|
|
node4.peerManager.switch.peerStore.connectedness(node1.switch.peerInfo.peerId) ==
|
|
Connected
|
|
node4.peerManager.switch.peerStore.peers().anyIt(
|
|
it.peerId == node2.switch.peerInfo.peerId
|
|
)
|
|
node4.peerManager.switch.peerStore.connectedness(node2.switch.peerInfo.peerId) ==
|
|
Connected
|
|
node4.peerManager.switch.peerStore.peers().anyIt(
|
|
it.peerId == node3.switch.peerInfo.peerId
|
|
)
|
|
node4.peerManager.switch.peerStore.connectedness(node3.switch.peerInfo.peerId) ==
|
|
Connected
|
|
|
|
await allFutures([node1.stop(), node2.stop(), node3.stop(), node4.stop()])
|