mirror of
https://github.com/logos-messaging/logos-delivery.git
synced 2026-07-17 10:10:09 +00:00
ce918b0819
* change all usage of std.options.Option[T] to results.Opt[T] * fix broken apps and examples (to validate refactor) * removed all std/options code added for libp2p v2 migration * add broker Opt codec to persistency/backend_comm.nim * add a readValue overload for Opt[T] in tools/confutils/cli_args.nim * keep Option where required (Presto, confutils' config_file.nim) * Change generateRlnProof error handling * Fix imports
132 lines
4.0 KiB
Nim
132 lines
4.0 KiB
Nim
import std/times
|
|
import confutils, chronicles, chronos, results
|
|
|
|
import logos_delivery/waku/[waku_core, common/protobuf]
|
|
import libp2p/protobuf/minprotobuf
|
|
|
|
export times, confutils, chronicles, chronos, results, waku_core, protobuf, minprotobuf
|
|
|
|
type SerializedKey* = seq[byte]
|
|
|
|
type WakuStealthCommitmentMsg* = object
|
|
request*: bool
|
|
spendingPubKey*: Opt[SerializedKey]
|
|
viewingPubKey*: Opt[SerializedKey]
|
|
ephemeralPubKey*: Opt[SerializedKey]
|
|
stealthCommitment*: Opt[SerializedKey]
|
|
viewTag*: Opt[uint64]
|
|
|
|
proc decode*(T: type WakuStealthCommitmentMsg, buffer: seq[byte]): ProtoResult[T] =
|
|
var msg = WakuStealthCommitmentMsg()
|
|
let pb = initProtoBuffer(buffer)
|
|
|
|
var request: uint64
|
|
discard ?pb.getField(1, request)
|
|
msg.request = request == 1
|
|
var spendingPubKey = newSeq[byte]()
|
|
discard ?pb.getField(2, spendingPubKey)
|
|
msg.spendingPubKey =
|
|
if spendingPubKey.len > 0:
|
|
Opt.some(spendingPubKey)
|
|
else:
|
|
Opt.none(SerializedKey)
|
|
var viewingPubKey = newSeq[byte]()
|
|
discard ?pb.getField(3, viewingPubKey)
|
|
msg.viewingPubKey =
|
|
if viewingPubKey.len > 0:
|
|
Opt.some(viewingPubKey)
|
|
else:
|
|
Opt.none(SerializedKey)
|
|
|
|
if msg.spendingPubKey.isSome() and msg.viewingPubKey.isSome():
|
|
msg.stealthCommitment = Opt.none(SerializedKey)
|
|
msg.viewTag = Opt.none(uint64)
|
|
return ok(msg)
|
|
if msg.spendingPubKey.isSome() and msg.viewingPubKey.isNone():
|
|
return err(ProtoError.RequiredFieldMissing)
|
|
if msg.spendingPubKey.isNone() and msg.viewingPubKey.isSome():
|
|
return err(ProtoError.RequiredFieldMissing)
|
|
if msg.request == true and msg.spendingPubKey.isNone() and msg.viewingPubKey.isNone():
|
|
return err(ProtoError.RequiredFieldMissing)
|
|
|
|
var stealthCommitment = newSeq[byte]()
|
|
discard ?pb.getField(4, stealthCommitment)
|
|
msg.stealthCommitment =
|
|
if stealthCommitment.len > 0:
|
|
Opt.some(stealthCommitment)
|
|
else:
|
|
Opt.none(SerializedKey)
|
|
|
|
var ephemeralPubKey = newSeq[byte]()
|
|
discard ?pb.getField(5, ephemeralPubKey)
|
|
msg.ephemeralPubKey =
|
|
if ephemeralPubKey.len > 0:
|
|
Opt.some(ephemeralPubKey)
|
|
else:
|
|
Opt.none(SerializedKey)
|
|
|
|
var viewTag: uint64
|
|
discard ?pb.getField(6, viewTag)
|
|
msg.viewTag =
|
|
if viewTag != 0:
|
|
Opt.some(viewTag)
|
|
else:
|
|
Opt.none(uint64)
|
|
|
|
if msg.stealthCommitment.isNone() and msg.viewTag.isNone() and
|
|
msg.ephemeralPubKey.isNone():
|
|
return err(ProtoError.RequiredFieldMissing)
|
|
|
|
if msg.stealthCommitment.isSome() and msg.viewTag.isNone():
|
|
return err(ProtoError.RequiredFieldMissing)
|
|
|
|
if msg.stealthCommitment.isNone() and msg.viewTag.isSome():
|
|
return err(ProtoError.RequiredFieldMissing)
|
|
|
|
if msg.stealthCommitment.isSome() and msg.viewTag.isSome():
|
|
msg.spendingPubKey = Opt.none(SerializedKey)
|
|
msg.viewingPubKey = Opt.none(SerializedKey)
|
|
|
|
ok(msg)
|
|
|
|
proc encode*(msg: WakuStealthCommitmentMsg): ProtoBuffer =
|
|
var serialised = initProtoBuffer()
|
|
|
|
serialised.write(1, uint64(msg.request))
|
|
|
|
if msg.spendingPubKey.isSome():
|
|
serialised.write(2, msg.spendingPubKey.get())
|
|
if msg.viewingPubKey.isSome():
|
|
serialised.write(3, msg.viewingPubKey.get())
|
|
if msg.stealthCommitment.isSome():
|
|
serialised.write(4, msg.stealthCommitment.get())
|
|
if msg.ephemeralPubKey.isSome():
|
|
serialised.write(5, msg.ephemeralPubKey.get())
|
|
if msg.viewTag.isSome():
|
|
serialised.write(6, msg.viewTag.get())
|
|
|
|
return serialised
|
|
|
|
func toByteSeq*(str: string): seq[byte] {.inline.} =
|
|
## Converts a string to the corresponding byte sequence.
|
|
@(str.toOpenArrayByte(0, str.high))
|
|
|
|
proc constructRequest*(
|
|
spendingPubKey: SerializedKey, viewingPubKey: SerializedKey
|
|
): WakuStealthCommitmentMsg =
|
|
WakuStealthCommitmentMsg(
|
|
request: true,
|
|
spendingPubKey: Opt.some(spendingPubKey),
|
|
viewingPubKey: Opt.some(viewingPubKey),
|
|
)
|
|
|
|
proc constructResponse*(
|
|
stealthCommitment: SerializedKey, ephemeralPubKey: SerializedKey, viewTag: uint64
|
|
): WakuStealthCommitmentMsg =
|
|
WakuStealthCommitmentMsg(
|
|
request: false,
|
|
stealthCommitment: Opt.some(stealthCommitment),
|
|
ephemeralPubKey: Opt.some(ephemeralPubKey),
|
|
viewTag: Opt.some(viewTag),
|
|
)
|