mirror of
https://github.com/codex-storage/nim-codex.git
synced 2025-01-09 20:45:38 +00:00
7efa9177df
* extra utilities and tweaks * add atlas lock * update ignores * break build into it's own script * update url rules * base off codexdht's * compile fixes for Nim 1.6.14 * update submodules * convert mapFailure to procs to work around type resolution issues * add toml parser for multiaddress * change error type on keyutils * bump nimbus build to use 1.6.14 * update gitignore * adding new deps submodules * bump nim ci version * even more fixes * more libp2p changes * update keys * fix eventually function * adding coverage test file * move coverage to build.nims * use nimcache/coverage * move libp2p import for tests into helper.nim * remove named bin * bug fixes for networkpeers (from Dmitriy) --------- Co-authored-by: Dmitriy Ryajov <dryajov@gmail.com>
94 lines
2.4 KiB
Nim
94 lines
2.4 KiB
Nim
import std/osproc
|
|
import std/os
|
|
import std/streams
|
|
import std/strutils
|
|
import pkg/ethers
|
|
import ./codexclient
|
|
|
|
const workingDir = currentSourcePath() / ".." / ".." / ".."
|
|
const executable = "build" / "codex"
|
|
|
|
type
|
|
NodeProcess* = ref object
|
|
process: Process
|
|
arguments: seq[string]
|
|
debug: bool
|
|
Role* {.pure.} = enum
|
|
Client,
|
|
Provider,
|
|
Validator
|
|
RunningNode* = ref object
|
|
role*: Role
|
|
node*: NodeProcess
|
|
restClient*: CodexClient
|
|
datadir*: string
|
|
ethAccount*: Address
|
|
StartNodes* = object
|
|
clients*: uint
|
|
providers*: uint
|
|
validators*: uint
|
|
DebugNodes* = object
|
|
client*: bool
|
|
provider*: bool
|
|
validator*: bool
|
|
topics*: string
|
|
|
|
proc new*(_: type RunningNode,
|
|
role: Role,
|
|
node: NodeProcess,
|
|
restClient: CodexClient,
|
|
datadir: string,
|
|
ethAccount: Address): RunningNode =
|
|
RunningNode(role: role,
|
|
node: node,
|
|
restClient: restClient,
|
|
datadir: datadir,
|
|
ethAccount: ethAccount)
|
|
|
|
proc init*(_: type StartNodes,
|
|
clients, providers, validators: uint): StartNodes =
|
|
StartNodes(clients: clients, providers: providers, validators: validators)
|
|
|
|
proc init*(_: type DebugNodes,
|
|
client, provider, validator: bool,
|
|
topics: string = "validator,proving,market"): DebugNodes =
|
|
DebugNodes(client: client, provider: provider, validator: validator,
|
|
topics: topics)
|
|
|
|
proc start(node: NodeProcess) =
|
|
if node.debug:
|
|
node.process = osproc.startProcess(
|
|
executable,
|
|
workingDir,
|
|
node.arguments,
|
|
options={poParentStreams}
|
|
)
|
|
sleep(1000)
|
|
else:
|
|
node.process = osproc.startProcess(
|
|
executable,
|
|
workingDir,
|
|
node.arguments
|
|
)
|
|
for line in node.process.outputStream.lines:
|
|
if line.contains("Started codex node"):
|
|
break
|
|
|
|
proc startNode*(args: openArray[string], debug: string | bool = false): NodeProcess =
|
|
## Starts a Codex Node with the specified arguments.
|
|
## Set debug to 'true' to see output of the node.
|
|
let node = NodeProcess(arguments: @args, debug: ($debug != "false"))
|
|
node.start()
|
|
node
|
|
|
|
proc stop*(node: NodeProcess) =
|
|
if node.process != nil:
|
|
node.process.terminate()
|
|
discard node.process.waitForExit(timeout=5_000)
|
|
node.process.close()
|
|
node.process = nil
|
|
|
|
proc restart*(node: NodeProcess) =
|
|
node.stop()
|
|
node.start()
|