mirror of
https://github.com/codex-storage/nim-codex.git
synced 2025-02-12 21:07:02 +00:00
7efa9177df
* extra utilities and tweaks * add atlas lock * update ignores * break build into it's own script * update url rules * base off codexdht's * compile fixes for Nim 1.6.14 * update submodules * convert mapFailure to procs to work around type resolution issues * add toml parser for multiaddress * change error type on keyutils * bump nimbus build to use 1.6.14 * update gitignore * adding new deps submodules * bump nim ci version * even more fixes * more libp2p changes * update keys * fix eventually function * adding coverage test file * move coverage to build.nims * use nimcache/coverage * move libp2p import for tests into helper.nim * remove named bin * bug fixes for networkpeers (from Dmitriy) --------- Co-authored-by: Dmitriy Ryajov <dryajov@gmail.com>
123 lines
3.6 KiB
Nim
123 lines
3.6 KiB
Nim
## Nim-Dagger
|
|
## Copyright (c) 2022 Status Research & Development GmbH
|
|
## Licensed under either of
|
|
## * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE))
|
|
## * MIT license ([LICENSE-MIT](LICENSE-MIT))
|
|
## at your option.
|
|
## This file may not be copied, modified, or distributed except according to
|
|
## those terms.
|
|
|
|
import std/options
|
|
|
|
import pkg/upraises
|
|
|
|
push: {.upraises: [].}
|
|
|
|
import pkg/chronos
|
|
import pkg/chronicles
|
|
import pkg/stew/ptrops
|
|
|
|
import ../stores
|
|
import ../manifest
|
|
import ../blocktype
|
|
|
|
import ./seekablestream
|
|
|
|
export stores, blocktype, manifest, chronos
|
|
|
|
logScope:
|
|
topics = "codex storestream"
|
|
|
|
const
|
|
StoreStreamTrackerName* = "StoreStream"
|
|
|
|
type
|
|
# Make SeekableStream from a sequence of blocks stored in Manifest
|
|
# (only original file data - see StoreStream.size)
|
|
StoreStream* = ref object of SeekableStream
|
|
store*: BlockStore # Store where to lookup block contents
|
|
manifest*: Manifest # List of block CIDs
|
|
pad*: bool # Pad last block to manifest.blockSize?
|
|
|
|
method initStream*(s: StoreStream) =
|
|
if s.objName.len == 0:
|
|
s.objName = StoreStreamTrackerName
|
|
|
|
procCall SeekableStream(s).initStream()
|
|
|
|
proc new*(
|
|
T: type StoreStream,
|
|
store: BlockStore,
|
|
manifest: Manifest,
|
|
pad = true
|
|
): StoreStream =
|
|
## Create a new StoreStream instance for a given store and manifest
|
|
##
|
|
result = StoreStream(
|
|
store: store,
|
|
manifest: manifest,
|
|
pad: pad,
|
|
offset: 0)
|
|
|
|
result.initStream()
|
|
|
|
method `size`*(self: StoreStream): int =
|
|
bytes(self.manifest, self.pad).int
|
|
|
|
proc `size=`*(self: StoreStream, size: int)
|
|
{.error: "Setting the size is forbidden".} =
|
|
discard
|
|
|
|
method atEof*(self: StoreStream): bool =
|
|
self.offset >= self.size
|
|
|
|
method readOnce*(
|
|
self: StoreStream,
|
|
pbytes: pointer,
|
|
nbytes: int
|
|
): Future[int] {.async.} =
|
|
## Read `nbytes` from current position in the StoreStream into output buffer pointed by `pbytes`.
|
|
## Return how many bytes were actually read before EOF was encountered.
|
|
## Raise exception if we are already at EOF.
|
|
##
|
|
|
|
trace "Reading from manifest", cid = self.manifest.cid.get(), blocks = self.manifest.len
|
|
if self.atEof:
|
|
raise newLPStreamEOFError()
|
|
|
|
# The loop iterates over blocks in the StoreStream,
|
|
# reading them and copying their data into outbuf
|
|
var read = 0 # Bytes read so far, and thus write offset in the outbuf
|
|
while read < nbytes and not self.atEof:
|
|
# Compute from the current stream position `self.offset` the block num/offset to read
|
|
# Compute how many bytes to read from this block
|
|
let
|
|
blockNum = self.offset div self.manifest.blockSize.int
|
|
blockOffset = self.offset mod self.manifest.blockSize.int
|
|
readBytes = min([self.size - self.offset,
|
|
nbytes - read,
|
|
self.manifest.blockSize.int - blockOffset])
|
|
|
|
# Read contents of block `blockNum`
|
|
without blk =? await self.store.getBlock(self.manifest[blockNum]), error:
|
|
raise newLPStreamReadError(error)
|
|
|
|
trace "Reading bytes from store stream", blockNum, cid = blk.cid, bytes = readBytes, blockOffset
|
|
|
|
# Copy `readBytes` bytes starting at `blockOffset` from the block into the outbuf
|
|
if blk.isEmpty:
|
|
zeroMem(pbytes.offset(read), readBytes)
|
|
else:
|
|
copyMem(pbytes.offset(read), blk.data[blockOffset].addr, readBytes)
|
|
|
|
# Update current positions in the stream and outbuf
|
|
self.offset += readBytes
|
|
read += readBytes
|
|
|
|
return read
|
|
|
|
method closeImpl*(self: StoreStream) {.async.} =
|
|
trace "Closing StoreStream"
|
|
self.offset = self.size # set Eof
|
|
await procCall LPStream(self).closeImpl()
|