mirror of
https://github.com/codex-storage/nim-codex.git
synced 2025-01-09 12:35:51 +00:00
de88fd2c53
* implement a logging proxy The logging proxy: - prevents the need to import chronicles (as well as export except toJson), - prevents the need to override `writeValue` or use or import nim-json-seralization elsewhere in the codebase, allowing for sole use of utils/json for de/serialization, - and handles json formatting correctly in chronicles json sinks * Rename logging -> logutils to avoid ambiguity with common names * clean up * add setProperty for JsonRecord, remove nim-json-serialization conflict * Allow specifying textlines and json format separately Not specifying a LogFormat will apply the formatting to both textlines and json sinks. Specifying a LogFormat will apply the formatting to only that sink. * remove unneeded usages of std/json We only need to import utils/json instead of std/json * move serialization from rest/json to utils/json so it can be shared * fix NoColors ambiguity Was causing unit tests to fail on Windows. * Remove nre usage to fix Windows error Windows was erroring with `could not load: pcre64.dll`. Instead of fixing that error, remove the pcre usage :) * Add logutils module doc * Shorten logutils.formatIt for `NBytes` Both json and textlines formatIt were not needed, and could be combined into one formatIt * remove debug integration test config debug output and logformat of json for integration test logs * Use ## module doc to support docgen * bump nim-poseidon2 to export fromBytes Before the changes in this branch, fromBytes was likely being resolved by nim-stew, or other dependency. With the changes in this branch, that dependency was removed and fromBytes could no longer be resolved. By exporting fromBytes from nim-poseidon, the correct resolution is now happening. * fixes to get compiling after rebasing master * Add support for Result types being logged using formatIt
95 lines
2.4 KiB
Nim
95 lines
2.4 KiB
Nim
## Nim-Codex
|
|
## Copyright (c) 2021 Status Research & Development GmbH
|
|
## Licensed under either of
|
|
## * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE))
|
|
## * MIT license ([LICENSE-MIT](LICENSE-MIT))
|
|
## at your option.
|
|
## This file may not be copied, modified, or distributed except according to
|
|
## those terms.
|
|
|
|
import pkg/upraises
|
|
push: {.upraises: [].}
|
|
|
|
import pkg/chronos
|
|
import pkg/libp2p
|
|
|
|
import ../protobuf/blockexc
|
|
import ../protobuf/message
|
|
import ../../errors
|
|
import ../../logutils
|
|
|
|
logScope:
|
|
topics = "codex blockexcnetworkpeer"
|
|
|
|
type
|
|
ConnProvider* = proc(): Future[Connection] {.gcsafe, closure.}
|
|
|
|
RPCHandler* = proc(peer: NetworkPeer, msg: Message): Future[void] {.gcsafe.}
|
|
|
|
NetworkPeer* = ref object of RootObj
|
|
id*: PeerId
|
|
handler*: RPCHandler
|
|
sendConn: Connection
|
|
getConn: ConnProvider
|
|
|
|
proc connected*(b: NetworkPeer): bool =
|
|
not(isNil(b.sendConn)) and
|
|
not(b.sendConn.closed or b.sendConn.atEof)
|
|
|
|
proc readLoop*(b: NetworkPeer, conn: Connection) {.async.} =
|
|
if isNil(conn):
|
|
return
|
|
|
|
try:
|
|
while not conn.atEof or not conn.closed:
|
|
let
|
|
data = await conn.readLp(MaxMessageSize.int)
|
|
msg = Message.protobufDecode(data).mapFailure().tryGet()
|
|
trace "Got message for peer", peer = b.id
|
|
await b.handler(b, msg)
|
|
except CatchableError as err:
|
|
warn "Exception in blockexc read loop", msg = err.msg
|
|
finally:
|
|
await conn.close()
|
|
|
|
proc connect*(b: NetworkPeer): Future[Connection] {.async.} =
|
|
if b.connected:
|
|
return b.sendConn
|
|
|
|
b.sendConn = await b.getConn()
|
|
asyncSpawn b.readLoop(b.sendConn)
|
|
return b.sendConn
|
|
|
|
proc send*(b: NetworkPeer, msg: Message) {.async.} =
|
|
let conn = await b.connect()
|
|
|
|
if isNil(conn):
|
|
trace "Unable to get send connection for peer message not sent", peer = b.id
|
|
return
|
|
|
|
trace "Sending message to remote", peer = b.id
|
|
await conn.writeLp(protobufEncode(msg))
|
|
|
|
proc broadcast*(b: NetworkPeer, msg: Message) =
|
|
proc sendAwaiter() {.async.} =
|
|
try:
|
|
await b.send(msg)
|
|
except CatchableError as exc:
|
|
trace "Exception broadcasting message to peer", peer = b.id, exc = exc.msg
|
|
|
|
asyncSpawn sendAwaiter()
|
|
|
|
func new*(
|
|
T: type NetworkPeer,
|
|
peer: PeerId,
|
|
connProvider: ConnProvider,
|
|
rpcHandler: RPCHandler): NetworkPeer =
|
|
|
|
doAssert(not isNil(connProvider),
|
|
"should supply connection provider")
|
|
|
|
NetworkPeer(
|
|
id: peer,
|
|
getConn: connProvider,
|
|
handler: rpcHandler)
|